Bump to 2.20.2

- Fix bugs that were causing XDMCP to not work properly.  (Robert
  Nelson and Brian Cameron)

- Fix so that XDMCP configuration options are read from the
  configuration file.  (Andrew Ziem)

- Fix bug with gdmXnestchooser where it wasn't starting Xephyr with
  the correct arguments.  (Andrew Ziem)

- Fix so that GDM allows setting of LC_TYPE without setting LANG.
  (Sjoerd Simons and Takao Fujiwara)

- Icon imporvements.  (Luca Ferretti)

- Fix leaks.  (Andrew Ziem)

(Portage version: 2.1.4_rc3)

4 files changed, 241 insertions, 1 deletions

diff --git a/gnome-base/gdm/ChangeLog b/gnome-base/gdm/ChangeLog
index ff7e5f0a154f..b96ce947f3e3 100644
--- a/gnome-base/gdm/ChangeLog
+++ b/gnome-base/gdm/ChangeLog
@@ -1,6 +1,27 @@
 # ChangeLog for gnome-base/gdm
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gdm/ChangeLog,v 1.253 2007/11/29 05:59:28 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gdm/ChangeLog,v 1.254 2007/11/29 16:46:42 dang Exp $
+
+*gdm-2.20.2 (29 Nov 2007)
+
+  29 Nov 2007; Daniel Gryniewicz <dang@gentoo.org>
+  +files/gdm-2.20.2-gksu.patch, +gdm-2.20.2.ebuild:
+  Bump to 2.20.2
+  - Fix bugs that were causing XDMCP to not work properly.  (Robert
+    Nelson and Brian Cameron)
+  
+  - Fix so that XDMCP configuration options are read from the 
+    configuration file.  (Andrew Ziem)
+  
+  - Fix bug with gdmXnestchooser where it wasn't starting Xephyr with
+    the correct arguments.  (Andrew Ziem)
+  
+  - Fix so that GDM allows setting of LC_TYPE without setting LANG.
+    (Sjoerd Simons and Takao Fujiwara)
+  
+  - Icon imporvements.  (Luca Ferretti)
+  
+  - Fix leaks.  (Andrew Ziem)
 
   29 Nov 2007; Jeroen Roovers <jer@gentoo.org> gdm-2.20.1.ebuild:
   Stable for HPPA (bug #199740).
diff --git a/gnome-base/gdm/files/digest-gdm-2.20.2 b/gnome-base/gdm/files/digest-gdm-2.20.2
new file mode 100644
index 000000000000..9f30204936a3
--- /dev/null
+++ b/gnome-base/gdm/files/digest-gdm-2.20.2
@@ -0,0 +1,9 @@
+MD5 65b5319561ce8464e35750f9c3d594fa gdm-2.20.2.tar.bz2 3892711
+RMD160 19d3bf99853391685a1d16b848c1d27a94502395 gdm-2.20.2.tar.bz2 3892711
+SHA256 5e0b3b66b8a9d84ddbe22f03f02a9ce05bdcf77e72973e0fdf44eac6e12a6d04 gdm-2.20.2.tar.bz2 3892711
+MD5 a23df5fecb624744c016ad2fe8ebe5e8 gdm-2.8-gentoo-files-r2.tar.bz2 3101
+RMD160 b1776e987bf87e7db34d73bdf7a8eebfdcd51e54 gdm-2.8-gentoo-files-r2.tar.bz2 3101
+SHA256 c9335d71ab0a2ceca6a5959947aabf3728031e86dcb5536b7b57c6115c4ce53e gdm-2.8-gentoo-files-r2.tar.bz2 3101
+MD5 146b311aea6ca3b6b9bdbe551cb7c0ae gentoo-gdm-theme-r3.tar.bz2 411703
+RMD160 9188c8f2661163be72595a6b4924fae0648e7df5 gentoo-gdm-theme-r3.tar.bz2 411703
+SHA256 c7cbe97757ff93f0ffd42f9d9fb702278a361e830940a03901cda9943f44ba68 gentoo-gdm-theme-r3.tar.bz2 411703
diff --git a/gnome-base/gdm/files/gdm-2.20.2-gksu.patch b/gnome-base/gdm/files/gdm-2.20.2-gksu.patch
new file mode 100644
index 000000000000..388917708047
--- /dev/null
+++ b/gnome-base/gdm/files/gdm-2.20.2-gksu.patch
@@ -0,0 +1,12 @@
+diff --exclude-from=/home/dang/.scripts/diffrc -up -ruN gdm-2.20.2.orig/gui/gdmsetup.desktop.in.in gdm-2.20.2/gui/gdmsetup.desktop.in.in
+--- gdm-2.20.2.orig/gui/gdmsetup.desktop.in.in	2007-11-26 18:11:04.000000000 -0500
++++ gdm-2.20.2/gui/gdmsetup.desktop.in.in	2007-11-29 11:40:38.000000000 -0500
+@@ -3,7 +3,7 @@ Encoding=UTF-8
+ _Name=Login Window
+ _Comment=Configure GDM login window appearance and behavior
+ TryExec=@sbindir@/gdmsetup
+-Exec=@sbindir@/gdmsetup
++Exec=gksu @sbindir@/gdmsetup
+ Icon=gdmsetup
+ StartupNotify=true
+ Terminal=false
diff --git a/gnome-base/gdm/gdm-2.20.2.ebuild b/gnome-base/gdm/gdm-2.20.2.ebuild
new file mode 100644
index 000000000000..95e0259ec60b
--- /dev/null
+++ b/gnome-base/gdm/gdm-2.20.2.ebuild
@@ -0,0 +1,198 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gdm/gdm-2.20.2.ebuild,v 1.1 2007/11/29 16:46:42 dang Exp $
+
+inherit autotools eutils pam gnome2
+
+DESCRIPTION="GNOME Display Manager"
+HOMEPAGE="http://www.gnome.org/projects/gdm/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+
+IUSE_LIBC="elibc_glibc"
+IUSE="accessibility afs branding dmx ipv6 pam remote selinux tcpd xinerama $IUSE_LIBC"
+
+# Name of the tarball with gentoo specific files
+GDM_EXTRA="${PN}-2.8-gentoo-files-r2"
+
+SRC_URI="${SRC_URI}
+		 mirror://gentoo/${GDM_EXTRA}.tar.bz2
+		 branding? ( mirror://gentoo/gentoo-gdm-theme-r3.tar.bz2 )"
+
+RDEPEND="dev-libs/dbus-glib
+		 >=dev-libs/glib-2.12
+		 >=x11-libs/gtk+-2.6
+		 >=x11-libs/pango-1.3
+		 >=gnome-base/libglade-2
+		 >=gnome-base/libgnomecanvas-2
+		 >=gnome-base/librsvg-1.1.1
+		 >=dev-libs/libxml2-2.4.12
+		 >=media-libs/libart_lgpl-2.3.11
+		 x11-libs/gksu
+		 x11-libs/libXi
+		 x11-libs/libXau
+		 x11-libs/libX11
+		 x11-libs/libXext
+		 x11-apps/sessreg
+		 x11-libs/libXdmcp
+		 xinerama? ( x11-libs/libXinerama )
+		 sys-auth/consolekit
+		 accessibility? ( x11-libs/libXevie )
+		 afs? ( net-fs/openafs sys-libs/lwp )
+		 dmx? ( x11-libs/libdmx )
+		 pam? ( virtual/pam )
+		 !pam? ( elibc_glibc? ( sys-apps/shadow ) )
+		 remote? ( gnome-extra/zenity )
+		 selinux? ( sys-libs/libselinux )
+		 tcpd? ( >=sys-apps/tcp-wrappers-7.6 )"
+DEPEND="${RDEPEND}
+		dmx? ( x11-proto/dmxproto )
+		sys-devel/gettext
+		x11-proto/inputproto
+		>=dev-util/intltool-0.35
+		>=dev-util/pkgconfig-0.19
+		>=app-text/scrollkeeper-0.1.4
+		>=app-text/gnome-doc-utils-0.3.2"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="--with-prefetch=yes               \
+			--sysconfdir=/etc/X11             \
+			--localstatedir=/var              \
+			--with-xdmcp=yes                  \
+			--with-pam-prefix=/etc            \
+			--with-console-kit=yes            \
+			$(use_enable accessibility xevie) \
+			$(use_enable ipv6)                \
+			$(use_enable remote secureremote) \
+			$(use_with selinux)               \
+			$(use_with tcpd tcp-wrappers)     \
+			$(use_with xinerama)"
+
+	if use dmx ; then
+		G2CONF="${G2CONF} --with-dmx=yes"
+	else
+		G2CONF="${G2CONF} --with-dmx=no"
+	fi
+
+	if use pam; then
+		G2CONF="${G2CONF} --enable-authentication-scheme=pam"
+	else
+		G2CONF="${G2CONF} --enable-console-helper=no"
+		if use elibc_glibc ; then
+			G2CONF="${G2CONF} --enable-authentication-scheme=shadow"
+		else
+			G2CONF="${G2CONF} --enable-authentication-scheme=crypt"
+		fi
+	fi
+
+	enewgroup gdm
+	enewuser gdm -1 -1 /var/lib/gdm gdm
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# remove unneeded linker directive for selinux (#41022)
+	epatch "${FILESDIR}/${PN}-2.13.0.1-selinux-remove-attr.patch"
+
+	# Add gksu to gdmsetup menu entry
+	epatch "${FILESDIR}/${PN}-2.20.2-gksu.patch"
+}
+
+src_install() {
+	gnome2_src_install
+
+	local gentoodir="${WORKDIR}/${GDM_EXTRA}"
+
+	# gdm-binary should be gdm to work with our init (#5598)
+	rm -f "${D}/usr/sbin/gdm"
+	dosym /usr/sbin/gdm-binary /usr/sbin/gdm
+
+	# our x11's scripts point to /usr/bin/gdm
+	dosym /usr/sbin/gdm-binary /usr/bin/gdm
+
+	# log, etc.
+	keepdir /var/log/gdm
+	keepdir /var/gdm
+
+	chown root:gdm "${D}/var/gdm"
+	chmod 1770 "${D}/var/gdm"
+
+	# use our own session script
+	rm -f "${D}/etc/X11/gdm/Xsession"
+	exeinto /etc/X11/gdm
+	doexe "${gentoodir}/Xsession"
+
+	# add a custom xsession .desktop by default (#44537)
+	exeinto /etc/X11/dm/Sessions
+	doexe "${gentoodir}/custom.desktop"
+
+	# We replace the pam stuff by our own
+	rm -rf "${D}/etc/pam.d"
+
+	if use pam ; then
+		dopamd "${gentoodir}"/pam.d/*
+		dopamsecurity console.apps "${gentoodir}/security/console.apps/gdmsetup"
+	fi
+
+	# use graphical greeter local
+	dosed "s:#Greeter=/usr/libexec/gdmlogin:Greeter=/usr/libexec/gdmgreeter:" \
+		/usr/share/gdm/defaults.conf
+
+	# list available users
+	dosed "s:^#MinimalUID=.*:MinimalUID=1000:" /usr/share/gdm/defaults.conf
+	dosed "s:^#IncludeAll=.*:IncludeAll=true:" /usr/share/gdm/defaults.conf
+
+	# Fix old X11R6 paths
+	dosed "s:/usr/X11R6/bin:/usr/bin:" /usr/share/gdm/defaults.conf
+
+	# Move Gentoo theme in
+	if use branding ; then
+		mv "${WORKDIR}"/gentoo-*  "${D}/usr/share/gdm/themes"
+	fi
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "To make GDM start at boot, edit /etc/rc.conf"
+	elog "and then execute 'rc-update add xdm default'."
+
+	elog "GDM has changed the location of its configuration file.  Please"
+	elog "edit /etc/X11/gdm/custom.conf.  The factory defaults are located"
+	elog "at /usr/share/gdm/{defaults.conf,factory-defaults.conf}"
+
+	elog "See README.install for more information about the change."
+
+	if [ -f "/etc/X11/gdm/gdm.conf" ]; then
+		elog "You had /etc/X11/gdm/gdm.conf which is the old configuration"
+		elog "file.  It has been moved to /etc/X11/gdm/gdm-pre-gnome-2.16"
+		mv /etc/X11/gdm/gdm.conf /etc/X11/gdm/gdm-pre-gnome-2.16
+	fi
+
+	# Soft restart, assumes Gentoo defaults for file locations
+	# Do restart after gdm.conf move above
+	FIFOFILE=/var/gdm/.gdmfifo
+	PIDFILE=/var/run/gdm.pid
+
+	if [ -w ${FIFOFILE} ] ; then
+		if [ -f ${PIDFILE} ] ; then
+			if kill -0 `cat ${PIDFILE}`; then
+				(echo;echo SOFT_RESTART) >> ${FIFOFILE}
+			fi
+		fi
+	fi
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	if [[ "$(rc-config list default | grep xdm)" != "" ]] ; then
+		elog "To remove GDM from startup please execute"
+		elog "'rc-update del xdm default'"
+	fi
+}