Version bump for Gnome 2.32

(Portage version: 2.1.9.14/cvs/Linux x86_64)

3 files changed, 115 insertions, 1 deletions

diff --git a/gnome-base/gconf/ChangeLog b/gnome-base/gconf/ChangeLog
index c50657d22fa7..37e49272372a 100644
--- a/gnome-base/gconf/ChangeLog
+++ b/gnome-base/gconf/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for gnome-base/gconf
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gconf/ChangeLog,v 1.234 2010/10/08 19:43:38 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gconf/ChangeLog,v 1.235 2010/10/12 18:36:52 pacho Exp $
+
+*gconf-2.32.0 (12 Oct 2010)
+
+  12 Oct 2010; Pacho Ramos <pacho@gentoo.org> +gconf-2.32.0.ebuild:
+  Version bump for Gnome 2.32: libgconf-2 was ported to the DBus bindings in
+  gio, and no longer links to libdbus, allow external orbit-idl-2 compiler
+  for cross-compiling, add a GSettings backend to ease the transition from
+  GConf to GSettings/DConf, bugfixes and translation updates. Added
+  introspection support.
 
   08 Oct 2010; Samuli Suominen <ssuominen@gentoo.org> gconf-2.28.1.ebuild:
   ppc64 stable wrt #324077
diff --git a/gnome-base/gconf/gconf-2.32.0.ebuild b/gnome-base/gconf/gconf-2.32.0.ebuild
new file mode 100644
index 000000000000..5225316232b1
--- /dev/null
+++ b/gnome-base/gconf/gconf-2.32.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gconf/gconf-2.32.0.ebuild,v 1.1 2010/10/12 18:36:52 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit eutils gnome2
+
+MY_PN=GConf
+MY_P=${MY_PN}-${PV}
+PVP=(${PV//[-\._]/ })
+
+DESCRIPTION="Gnome Configuration System and Daemon"
+HOMEPAGE="http://www.gnome.org/"
+SRC_URI="mirror://gnome/sources/${MY_PN}/${PVP[0]}.${PVP[1]}/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc +introspection ldap policykit"
+
+RDEPEND=">=dev-libs/glib-2.25.9
+	>=x11-libs/gtk+-2.14
+	>=dev-libs/dbus-glib-0.74
+	>=sys-apps/dbus-1
+	>=gnome-base/orbit-2.4
+	>=dev-libs/libxml2-2
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	ldap? ( net-nds/openldap )
+	policykit? ( sys-auth/polkit )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/gtk-doc-am-1.10
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog NEWS README TODO"
+	G2CONF="${G2CONF}
+		--enable-gtk
+		--disable-static
+		--enable-gsettings-backend
+		$(use_enable introspection)
+		$(use_with ldap openldap)
+		$(use_enable policykit defaults-service)"
+	kill_gconf
+
+	# Need host's IDL compiler for cross or native build, bug #262747
+	export EXTRA_EMAKE="${EXTRA_EMAKE} ORBIT_IDL=/usr/bin/orbit-idl-2"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Do not start gconfd when installing schemas, fix bug #238276, upstream #631983
+	epatch "${FILESDIR}/${PN}-2.24.0-no-gconfd.patch"
+
+	# Do not crash in gconf_entry_set_value() when entry pointer is NULL, upstream #631985
+	epatch "${FILESDIR}/${PN}-2.28.0-entry-set-value-sigsegv.patch"
+}
+
+src_install() {
+	gnome2_src_install
+
+	keepdir /etc/gconf/gconf.xml.mandatory
+	keepdir /etc/gconf/gconf.xml.defaults
+	# Make sure this directory exists, bug #268070, upstream #572027
+	keepdir /etc/gconf/gconf.xml.system
+
+	echo 'CONFIG_PROTECT_MASK="/etc/gconf"' > 50gconf
+	doenvd 50gconf || die "doenv failed"
+	dodir /root/.gconfd || die
+}
+
+pkg_preinst() {
+	kill_gconf
+}
+
+pkg_postinst() {
+	kill_gconf
+
+	# change the permissions to avoid some gconf bugs
+	einfo "changing permissions for gconf dirs"
+	find  /etc/gconf/ -type d -exec chmod ugo+rx "{}" \;
+
+	einfo "changing permissions for gconf files"
+	find  /etc/gconf/ -type f -exec chmod ugo+r "{}" \;
+}
+
+kill_gconf() {
+	# This function will kill all running gconfd-2 that could be causing troubles
+	if [ -x /usr/bin/gconftool-2 ]
+	then
+		/usr/bin/gconftool-2 --shutdown
+	fi
+
+	return 0
+}
diff --git a/gnome-base/gconf/metadata.xml b/gnome-base/gconf/metadata.xml
index da6fd63d0085..14e9fc116023 100644
--- a/gnome-base/gconf/metadata.xml
+++ b/gnome-base/gconf/metadata.xml
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+	<flag name="introspection">Use
+	<pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
+</use>
 </pkgmetadata>