Version bump, bug #180453

(Portage version: 2.1.2.7)

3 files changed, 139 insertions, 1 deletions

diff --git a/games-fps/nexuiz/ChangeLog b/games-fps/nexuiz/ChangeLog
index 65c89aa3ae20..0d12a4924238 100644
--- a/games-fps/nexuiz/ChangeLog
+++ b/games-fps/nexuiz/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-fps/nexuiz
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.21 2007/02/09 17:39:42 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/ChangeLog,v 1.22 2007/05/31 20:52:58 nyhm Exp $
+
+*nexuiz-2.3 (31 May 2007)
+
+  31 May 2007; Tristan Heaven <nyhm@gentoo.org> +nexuiz-2.3.ebuild:
+  Version bump, bug #180453
 
   09 Feb 2007; Michael Sterrett <mr_bones_@gentoo.org> -nexuiz-2.1.ebuild,
   nexuiz-2.2.3.ebuild:
diff --git a/games-fps/nexuiz/files/digest-nexuiz-2.3 b/games-fps/nexuiz/files/digest-nexuiz-2.3
new file mode 100644
index 000000000000..3467869261fc
--- /dev/null
+++ b/games-fps/nexuiz/files/digest-nexuiz-2.3
@@ -0,0 +1,6 @@
+MD5 e881e78e02e5e97c7c453192aab58f7d nexmappack_r2.zip 113533483
+RMD160 8fbf25ba69ecbaa8170aa468d29ee2f04df5b7f4 nexmappack_r2.zip 113533483
+SHA256 15088c7632e0b4f487c789fba4296f44ef5a5d83b51adcb9e603e289e5b8241e nexmappack_r2.zip 113533483
+MD5 b60c1f5198135463d00261646ae26911 nexuiz-23.zip 286217879
+RMD160 287b89bcffa4fe5d72d2b14eda45169f86220fc3 nexuiz-23.zip 286217879
+SHA256 232c08f3e0fa67ca3fd63995d3f6c88cbb9f771c96d4159c085151906cc43074 nexuiz-23.zip 286217879
diff --git a/games-fps/nexuiz/nexuiz-2.3.ebuild b/games-fps/nexuiz/nexuiz-2.3.ebuild
new file mode 100644
index 000000000000..4e0a1e0f11f8
--- /dev/null
+++ b/games-fps/nexuiz/nexuiz-2.3.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/nexuiz/nexuiz-2.3.ebuild,v 1.1 2007/05/31 20:52:58 nyhm Exp $
+
+inherit eutils toolchain-funcs games
+
+MY_PN=Nexuiz
+MY_P=${PN}-${PV//./}
+MAPS=nexmappack_r2
+DESCRIPTION="Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.nexuiz.com/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip
+	maps? ( mirror://sourceforge/${PN}/${MAPS}.zip )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dedicated maps opengl sdl"
+
+UIRDEPEND="alsa? ( media-libs/alsa-lib )
+	media-libs/libogg
+	media-libs/libvorbis
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm"
+UIDEPEND="x11-proto/xextproto
+	x11-proto/xf86dgaproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xproto"
+RDEPEND="media-libs/jpeg
+	net-misc/curl
+	sdl? ( media-libs/libsdl ${UIRDEPEND} )
+	opengl? ( virtual/opengl ${UIRDEPEND} )
+	!dedicated? ( !sdl? ( !opengl? ( virtual/opengl ${UIRDEPEND} ) ) )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	sdl? ( media-libs/libsdl ${UIDEPEND} )
+	opengl? ( virtual/opengl ${UIDEPEND} )
+	!dedicated? ( !sdl? ( !opengl? ( virtual/opengl ${UIDEPEND} ) ) )"
+
+S=${WORKDIR}/darkplaces
+
+src_unpack() {
+	unpack ${MY_P}.zip
+
+	local f
+	for f in "${MY_PN}"/sources/*.zip ; do
+		unpack ./${f}
+	done
+
+	if use maps ; then
+		cd "${WORKDIR}"/${MY_PN}
+		unpack ${MAPS}.zip
+	fi
+
+	cd "${S}"
+	# Make the game automatically look in the correct data directory
+	sed -i "s:gamedirname1:\"${PN}\":" fs.c \
+		|| die "sed fs.c failed"
+
+	sed -i \
+		-e "/^CC=/s:gcc:$(tc-getCC):" \
+		-e "s/-O2/${CFLAGS}/" \
+		-e "/-lm/s:$: ${LDFLAGS}:" \
+		-e '/strip/d' \
+		makefile.inc \
+		|| die "sed makefile.inc failed"
+
+	# This is the right dir, so that e.g. "darkplaces -game nexuiz" will work
+	sed -i "s:ifdef DP_.*:DP_FS_BASEDIR=${GAMES_DATADIR}/quake1\n&:" makefile \
+		|| die "sed makefile failed"
+
+	if ! use alsa ; then
+		sed -i "/DEFAULT_SNDAPI/s:ALSA:OSS:" makefile \
+			|| die "sed makefile failed"
+	fi
+}
+
+src_compile() {
+	if use opengl || (! use dedicated && ! use sdl) ; then
+		emake cl-${PN} || die "emake cl-${PN} failed"
+	fi
+
+	if use sdl ; then
+		emake sdl-${PN} || die "emake sdl-${PN} failed"
+	fi
+
+	if use dedicated ; then
+		emake sv-${PN} || die "emake sv-${PN} failed"
+	fi
+}
+
+src_install() {
+	if use opengl || use sdl || ! use dedicated ; then
+		newicon darkplaces72x72.png ${PN}.png
+	fi
+
+	if use opengl || (! use dedicated && ! use sdl) ; then
+		dogamesbin ${PN}-glx || die "dogamesbin glx failed"
+		make_desktop_entry ${PN}-glx "Nexuiz (GLX)"
+		dosym ${PN}-glx "${GAMES_BINDIR}"/${PN}
+	fi
+
+	if use sdl ; then
+		dogamesbin ${PN}-sdl || die "dogamesbin sdl failed"
+		make_desktop_entry ${PN}-sdl "Nexuiz (SDL)"
+		use opengl || dosym ${PN}-sdl "${GAMES_BINDIR}"/${PN}
+	fi
+
+	if use dedicated ; then
+		dogamesbin ${PN}-dedicated || die "dogamesbin dedicated failed"
+	fi
+
+	cd "${WORKDIR}"/${MY_PN}
+	insinto "${GAMES_DATADIR}"/quake1/${PN}
+	doins -r data/* || die "doins data failed"
+
+	dodoc Docs/*.txt
+	dohtml Docs/*.{htm,html}
+	docinto server
+	dodoc Docs/server/*.{cfg,txt}
+
+	prepgamesdirs
+}