Initial commit, ebuild by Robin H. Johnson <robbat2@gentoo.org>.

(Portage version: 2.2.17/cvs/Linux x86_64, unsigned Manifest commit)

4 files changed, 108 insertions, 0 deletions

diff --git a/dev-vcs/notify-webhook/ChangeLog b/dev-vcs/notify-webhook/ChangeLog
new file mode 100644
index 000000000000..636ddc590810
--- /dev/null
+++ b/dev-vcs/notify-webhook/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for dev-vcs/notify-webhook
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/notify-webhook/ChangeLog,v 1.1 2015/03/09 00:51:59 robbat2 Exp $
+
+*notify-webhook-20150308 (09 Mar 2015)
+*notify-webhook-20140805 (09 Mar 2015)
+
+  09 Mar 2015; Robin H. Johnson <robbat2@gentoo.org> +metadata.xml,
+  +notify-webhook-20140805.ebuild, +notify-webhook-20150308.ebuild:
+  Initial commit, ebuild by Robin H. Johnson <robbat2@gentoo.org>.
diff --git a/dev-vcs/notify-webhook/metadata.xml b/dev-vcs/notify-webhook/metadata.xml
new file mode 100644
index 000000000000..be611320454c
--- /dev/null
+++ b/dev-vcs/notify-webhook/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer>
+  <email>robbat2@gentoo.org</email>
+</maintainer>
+<longdescription lang="en">
+	notify-webhook is a git post-receive hook script that posts JSON data to a
+	webhook capable server.
+
+	This implements the GitHub Web hooks API as closely as possible. It allows
+	arbitrary git repositories to use webhook capable services.
+  </longdescription>
+</pkgmetadata>
diff --git a/dev-vcs/notify-webhook/notify-webhook-20140805.ebuild b/dev-vcs/notify-webhook/notify-webhook-20140805.ebuild
new file mode 100644
index 000000000000..7fc26e1edaa2
--- /dev/null
+++ b/dev-vcs/notify-webhook/notify-webhook-20140805.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/notify-webhook/notify-webhook-20140805.ebuild,v 1.1 2015/03/09 00:51:59 robbat2 Exp $
+
+EAPI=5
+
+DESCRIPTION="Git post-receive web hook notifier in Python."
+HOMEPAGE="https://github.com/metajack/notify-webhook"
+COMMIT='c571160f155122446e97bb01c1150b4d14ea69d6'
+SRC_URI="https://github.com/metajack/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-python/simplejson"
+RDEPEND="${DEPEND}"
+
+MY_P="${PN}-${COMMIT}"
+S="${WORKDIR}/${MY_P}"
+
+src_install() {
+	dodoc *markdown
+	exeinto /usr/libexec/githook/$PN/
+	doexe notify-webhook.py
+}
diff --git a/dev-vcs/notify-webhook/notify-webhook-20150308.ebuild b/dev-vcs/notify-webhook/notify-webhook-20150308.ebuild
new file mode 100644
index 000000000000..6cb5c261267b
--- /dev/null
+++ b/dev-vcs/notify-webhook/notify-webhook-20150308.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/notify-webhook/notify-webhook-20150308.ebuild,v 1.1 2015/03/09 00:51:59 robbat2 Exp $
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Git post-receive web hook notifier in Python."
+HOMEPAGE="https://github.com/metajack/notify-webhook"
+COMMIT='1ff39853e59bb0ee37c4783da8dcf3ea14cef53f'
+PATCH_COMMIT='BCLibCoop:ee038b53a48e70d9e69c86386c39b7f24736d07e'
+PATCH_DELTA="${COMMIT:0:7}...${PATCH_COMMIT:0:17}"
+PATCH_NAME="${P}-${PATCH_DELTA}.patch"
+SRC_URI="https://github.com/metajack/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz
+         https://github.com/metajack/notify-webhook/compare/${PATCH_DELTA}.patch -> ${PATCH_NAME}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-python/simplejson"
+DEPEND="${RDEPEND}
+		dev-util/patchutils"
+
+MY_P="${PN}-${COMMIT}"
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+}
+
+# Yes, this is some creative patch mangling, to avoid a manually created
+# distfile. epatch's dryrun fails on a sequence of changes that depend on each
+# other, so we can clean up the patch to actually pass that check.
+src_prepare() {
+	cd "${T}"
+	cp "${DISTDIR}/${PATCH_NAME}" diff
+	p="newdiff"
+	>$p # Make an empty file to work in
+	splitdiff -a -p 1 diff # split out the patches
+	# combine them to a single patch
+	for f in diff.part*.patch ; do
+		combinediff -p 1 $p $f >$p.new && mv $p.new $p
+	done
+
+	# Now apply it, and dry-run will pass too!
+	cd "${S}"
+	EPATCH_OPTS="-p1" epatch "${T}"/newdiff
+}
+
+src_install() {
+	dodoc *markdown
+	exeinto /usr/libexec/githook/$PN/
+	doexe notify-webhook.py
+}