Initial commit.

(Portage version: 2.2_rc12/cvs/Linux 2.6.27 x86_64, RepoMan options: --force)

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-util/nvidia-cuda-sdk/nvidia-cuda-sdk-2.02.0807.1535.ebuild b/dev-util/nvidia-cuda-sdk/nvidia-cuda-sdk-2.02.0807.1535.ebuild
new file mode 100644
index 000000000000..d751ace04b22
--- /dev/null
+++ b/dev-util/nvidia-cuda-sdk/nvidia-cuda-sdk-2.02.0807.1535.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/nvidia-cuda-sdk/nvidia-cuda-sdk-2.02.0807.1535.ebuild,v 1.1 2008/10/18 21:07:43 spock Exp $
+
+inherit eutils
+
+DESCRIPTION="NVIDIA CUDA Toolkit"
+HOMEPAGE="http://developer.nvidia.com/cuda"
+
+SRC_URI="http://developer.download.nvidia.com/compute/cuda/2_0/linux/sdk/NVIDIA_CUDA_SDK_${PV}_linux.run"
+LICENSE="CUDPP"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug emulation"
+
+DEPEND="dev-util/nvidia-cuda-toolkit
+	>=x11-drivers/nvidia-drivers-177.73"
+RESTRICT="strip"
+
+S="${WORKDIR}"
+
+src_unpack() {
+	unpack_makeself
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-make_cpp_fix.patch"
+}
+
+src_compile() {
+	local myopts=""
+
+	if use emulation; then
+		myopts="emu=1"
+	fi
+
+	if use debug; then
+		myopts="${myopts} dbg=1"
+	fi
+
+	cd "${S}/sdk"
+	emake cuda-install=/opt/cuda ${myopts} || die
+}
+
+src_install() {
+	cd "${S}/sdk"
+
+	for f in $(find .); do
+		local t="$(dirname ${f})"
+		if [[ "${t/obj\/}" != "${t}" || "${t##*.}" == "a" ]]; then
+			continue
+		fi
+
+		if [[ -x "${f}" && ! -d "${f}" ]]; then
+			exeinto "/opt/cuda/sdk/$(dirname ${f})"
+			doexe "${f}"
+		else
+			insinto "/opt/cuda/sdk/$(dirname ${f})"
+			doins "${f}"
+		fi
+	done
+}