Version bumps.

(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

3 files changed, 211 insertions, 1 deletions

diff --git a/dev-util/eric/ChangeLog b/dev-util/eric/ChangeLog
index dfd15a978649..f85e00e69ce5 100644
--- a/dev-util/eric/ChangeLog
+++ b/dev-util/eric/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/eric
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.180 2012/08/02 20:20:59 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.181 2012/08/12 19:23:13 pesa Exp $
+
+*eric-5.2.4 (12 Aug 2012)
+*eric-4.5.5 (12 Aug 2012)
+
+  12 Aug 2012; Davide Pesavento <pesa@gentoo.org> +eric-4.5.5.ebuild,
+  +eric-5.2.4.ebuild:
+  Version bumps.
 
   02 Aug 2012; Davide Pesavento <pesa@gentoo.org> -eric-4.5.3.ebuild,
   -eric-5.2.2.ebuild, eric-4.5.4.ebuild, eric-5.2.3.ebuild:
diff --git a/dev-util/eric/eric-4.5.5.ebuild b/dev-util/eric/eric-4.5.5.ebuild
new file mode 100644
index 000000000000..f0a0f809921e
--- /dev/null
+++ b/dev-util/eric/eric-4.5.5.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-4.5.5.ebuild,v 1.1 2012/08/12 19:23:13 pesa Exp $
+
+EAPI="4"
+PYTHON_DEPEND="2:2.6"
+SUPPORT_PYTHON_ABIS="1"
+# 2.4 and 2.5 are restricted to avoid conditional dependency on dev-python/simplejson.
+RESTRICT_PYTHON_ABIS="2.4 2.5 3.* *-jython 2.7-pypy-*"
+
+inherit eutils python
+
+SLOT="4"
+MY_PN="${PN}${SLOT}"
+MY_PV="${PV/_pre/-snapshot-}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+BASE_URI="mirror://sourceforge/eric-ide/${MY_PN}/stable/${PV}"
+SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="kde spell"
+
+DEPEND="
+	>=dev-python/sip-4.12.4
+	>=dev-python/PyQt4-4.6[assistant,svg,webkit,X]
+	>=dev-python/qscintilla-python-2.3
+	kde? ( kde-base/pykde4 )
+"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-2.0.1
+	>=dev-python/coverage-3.0.1
+	>=dev-python/pygments-1.3.1
+"
+PDEPEND="
+	spell? ( dev-python/pyenchant )
+"
+
+LANGS="cs de en es fr it ru tr zh_CN"
+for L in ${LANGS}; do
+	SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${MY_PN}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
+	IUSE+=" linguas_${L}"
+done
+unset L
+
+S=${WORKDIR}/${MY_P}
+
+PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
+
+src_prepare() {
+	epatch "${FILESDIR}/eric-4.4-no-interactive.patch"
+	use kde || epatch "${FILESDIR}/eric-4.4-no-pykde.patch"
+
+	# Delete internal copies of dev-python/chardet, dev-python/coverage,
+	# dev-python/pygments and dev-python/simplejson.
+	rm -fr eric/ThirdParty
+	rm -fr eric/DebugClients/Python{,3}/coverage
+	sed -i -e '\|/coverage/|d' eric/${MY_PN}.e4p || die
+	sed -i -e 's/from DebugClients\.Python3\?\.coverage /from coverage /' \
+		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+}
+
+src_install() {
+	installation() {
+		"$(PYTHON)" install.py \
+			-z \
+			-b "${EPREFIX}/usr/bin" \
+			-i "${T}/images/${PYTHON_ABI}" \
+			-d "${EPREFIX}$(python_get_sitedir)" \
+			-c
+	}
+	python_execute_function installation
+	python_merge_intermediate_installation_images "${T}/images"
+
+	doicon eric/icons/default/eric.png || die
+	make_desktop_entry "${MY_PN} --nosplash" ${MY_PN} eric "Development;IDE;Qt"
+}
+
+pkg_postinst() {
+	python_mod_optimize ${MY_PN}{,config.py,plugins}
+
+	elog
+	elog "If you want to use Eric with mod_python, have a look at"
+	elog "\"${EROOT}$(python_get_sitedir -b -f)/${MY_PN}/patch_modpython.py\"."
+	elog
+	elog "The following packages will give Eric extended functionality:"
+	elog "  dev-python/pylint"
+	elog "  dev-python/pysvn"
+	elog
+	elog "This version has a plugin interface with plugin-autofetch from"
+	elog "the application itself. You may want to check those as well."
+	elog
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${MY_PN}{,config.py,plugins}
+}
diff --git a/dev-util/eric/eric-5.2.4.ebuild b/dev-util/eric/eric-5.2.4.ebuild
new file mode 100644
index 000000000000..57cca65c419f
--- /dev/null
+++ b/dev-util/eric/eric-5.2.4.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-5.2.4.ebuild,v 1.1 2012/08/12 19:23:13 pesa Exp $
+
+EAPI="4"
+PYTHON_DEPEND="3:3.1"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.* *-jython 2.7-pypy-*"
+
+inherit eutils python
+
+SLOT="5"
+MY_PN="${PN}${SLOT}"
+MY_PV="${PV/_pre/-snapshot-}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+BASE_URI="mirror://sourceforge/eric-ide/${MY_PN}/stable/${PV}"
+SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="spell"
+
+DEPEND="
+	>=dev-python/sip-4.12.4
+	>=dev-python/PyQt4-4.8[assistant,svg,webkit,X]
+	>=dev-python/qscintilla-python-2.4
+"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-2.0.1
+	>=dev-python/coverage-3.2
+	>=dev-python/pygments-1.4
+"
+PDEPEND="
+	spell? ( dev-python/pyenchant )
+"
+
+LANGS="cs de en es fr it ru tr zh_CN"
+for L in ${LANGS}; do
+	SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${MY_PN}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
+	IUSE+=" linguas_${L}"
+done
+unset L
+
+S=${WORKDIR}/${MY_P}
+
+PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
+
+src_prepare() {
+	# Avoid file collisions between different slots of Eric.
+	sed -e "s/^Icon=eric$/&${SLOT}/" -i eric/${MY_PN}.desktop || die
+	sed -e "s/\([^[:alnum:]]\)eric\.png\([^[:alnum:]]\)/\1eric5.png\2/" \
+		-i $(grep -lr "eric\.png" .) || die
+	mv eric/icons/default/eric{,5}.png || die
+	mv eric/pixmaps/eric{,5}.png || die
+	rm -f eric/APIs/Python/zope-*.api
+	rm -f eric/APIs/Ruby/Ruby-*.api
+
+	# Delete internal copies of dev-python/chardet,
+	# dev-python/coverage and dev-python/pygments.
+	rm -fr eric/ThirdParty
+	rm -fr eric/DebugClients/Python{,3}/coverage
+	sed -i -e '\|/coverage/|d' eric/${MY_PN}.e4p || die
+	sed -i -e 's/from DebugClients\.Python3\?\.coverage /from coverage /' \
+		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+}
+
+src_install() {
+	installation() {
+		"$(PYTHON)" install.py \
+			-z \
+			-b "${EPREFIX}/usr/bin" \
+			-i "${T}/images/${PYTHON_ABI}" \
+			-d "${EPREFIX}$(python_get_sitedir)" \
+			-c
+	}
+	python_execute_function installation
+	python_merge_intermediate_installation_images "${T}/images"
+
+	doicon eric/icons/default/${MY_PN}.png || die
+}
+
+pkg_postinst() {
+	python_mod_optimize -x "/eric5/(DebugClients/Python|UtilitiesPython2)/" ${MY_PN}{,config.py,plugins}
+
+	elog
+	elog "If you want to use Eric with mod_python, have a look at"
+	elog "\"${EROOT}$(python_get_sitedir -b -f)/${MY_PN}/patch_modpython.py\"."
+	elog
+	elog "The following packages will give Eric extended functionality:"
+	elog "  dev-python/pylint"
+	elog "  dev-python/pysvn"
+	elog
+	elog "This version has a plugin interface with plugin-autofetch from"
+	elog "the application itself. You may want to check those as well."
+	elog
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${MY_PN}{,config.py,plugins}
+}