SVG is no longer optional but needs to be present in cairo. Fix running of tests. Block cairo-1.10.x since this version is not compatible with it.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 86 insertions, 1 deletions

diff --git a/dev-ruby/rcairo/ChangeLog b/dev-ruby/rcairo/ChangeLog
index 405f0d3abd72..c81a4e49b6c8 100644
--- a/dev-ruby/rcairo/ChangeLog
+++ b/dev-ruby/rcairo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.42 2010/09/18 13:57:56 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.43 2010/09/29 18:03:40 graaff Exp $
+
+*rcairo-1.8.5-r1 (29 Sep 2010)
+
+  29 Sep 2010; Hans de Graaff <graaff@gentoo.org> +rcairo-1.8.5-r1.ebuild:
+  SVG is no longer optional but needs to be present in cairo. Fix running of
+  tests. Block cairo-1.10.x since this version is not compatible with it.
 
 *rcairo-1.8.5 (18 Sep 2010)
 
diff --git a/dev-ruby/rcairo/rcairo-1.8.5-r1.ebuild b/dev-ruby/rcairo/rcairo-1.8.5-r1.ebuild
new file mode 100644
index 000000000000..9925ea0f3fd3
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.8.5-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.8.5-r1.ebuild,v 1.1 2010/09/29 18:03:40 graaff Exp $
+
+EAPI=2
+
+# ruby19 → fails, and even crashes Ruby
+# jruby → cannot work, it's a compiled extension
+USE_RUBY="ruby18"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Depends on test-unit-2 which is currently masked.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
+
+inherit multilib ruby-fakegem
+
+IUSE=""
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="http://cairographics.org/rcairo/"
+SRC_URI="mirror://rubygems/cairo-${PV}.gem"
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
+
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg]
+	<x11-libs/cairo-1.10"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg]
+	<x11-libs/cairo-1.10
+	dev-util/pkgconfig"
+
+ruby_add_bdepend "test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+all_ruby_prepare() {
+	# it fails, badly, as it expects the .pc to be frozen in time,
+	# which it isn't...
+	rm test/test_pkg_config.rb || die
+
+	# fix two strange assert calls
+	sed -i \
+		-e 's:assert_true(:assert(:' \
+		-e 's:assert_false(:assert(!:' \
+		test/test_exception.rb \
+		test/test_constants.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+	emake || die "make failed"
+
+	# again, try to make it more standard, to install it more easily.
+	cp ext/cairo/cairo$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	# don't rely on the Rakefile because it's a mess to load with
+	# their hierarchy, do it manually.
+	${RUBY} -Ilib -r test/unit -r ./test/cairo-test-utils.rb \
+		-e 'Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/samples
+	doins -r samples/* || die "Cannot install sample files."
+}