Version bump.

(Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

2 files changed, 120 insertions, 1 deletions

diff --git a/dev-qt/qtdemo/ChangeLog b/dev-qt/qtdemo/ChangeLog
index 7736c455b3cf..c59f47d212f5 100644
--- a/dev-qt/qtdemo/ChangeLog
+++ b/dev-qt/qtdemo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-qt/qtdemo
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v 1.3 2013/04/08 16:56:00 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/ChangeLog,v 1.4 2013/07/09 10:47:30 pesa Exp $
+
+*qtdemo-4.8.5 (09 Jul 2013)
+
+  09 Jul 2013; Davide Pesavento <pesa@gentoo.org> +qtdemo-4.8.5.ebuild:
+  Version bump.
 
   08 Apr 2013; Sergey Popov <pinkbyte@gentoo.org> qtdemo-4.8.4.ebuild:
   Add ~arm keyword, wrt bug #454916
diff --git a/dev-qt/qtdemo/qtdemo-4.8.5.ebuild b/dev-qt/qtdemo/qtdemo-4.8.5.ebuild
new file mode 100644
index 000000000000..393f63272fb7
--- /dev/null
+++ b/dev-qt/qtdemo/qtdemo-4.8.5.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtdemo/qtdemo-4.8.5.ebuild,v 1.1 2013/07/09 10:47:30 pesa Exp $
+
+EAPI=4
+
+inherit qt4-build
+
+DESCRIPTION="Demonstration module and examples for the Qt toolkit"
+SLOT="4"
+if [[ ${QT4_BUILD_TYPE} == live ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x64-macos"
+fi
+IUSE="dbus declarative kde multimedia opengl openvg qt3support webkit xmlpatterns"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}:4[aqua=,debug=,qt3support?]
+	~dev-qt/qtgui-${PV}:4[aqua=,debug=,qt3support?]
+	~dev-qt/qthelp-${PV}:4[aqua=,debug=]
+	~dev-qt/qtscript-${PV}:4[aqua=,debug=]
+	~dev-qt/qtsql-${PV}:4[aqua=,debug=,qt3support?]
+	~dev-qt/qtsvg-${PV}:4[aqua=,debug=]
+	~dev-qt/qttest-${PV}:4[aqua=,debug=]
+	dbus? ( ~dev-qt/qtdbus-${PV}:4[aqua=,debug=] )
+	declarative? ( ~dev-qt/qtdeclarative-${PV}:4[aqua=,debug=,webkit?] )
+	kde? ( media-libs/phonon[aqua=] )
+	!kde? ( || (
+		~dev-qt/qtphonon-${PV}:4[aqua=,debug=]
+		media-libs/phonon[aqua=]
+	) )
+	multimedia? ( ~dev-qt/qtmultimedia-${PV}:4[aqua=,debug=] )
+	opengl? ( ~dev-qt/qtopengl-${PV}:4[aqua=,debug=,qt3support?] )
+	openvg? ( ~dev-qt/qtopenvg-${PV}:4[aqua=,debug=,qt3support?] )
+	qt3support? ( ~dev-qt/qt3support-${PV}:4[aqua=,debug=] )
+	webkit? ( ~dev-qt/qtwebkit-${PV}:4[aqua=,debug=] )
+	xmlpatterns? ( ~dev-qt/qtxmlpatterns-${PV}:4[aqua=,debug=] )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.6-plugandpaint.patch"
+)
+
+pkg_setup() {
+	QT4_TARGET_DIRECTORIES="
+		demos
+		examples"
+	QT4_EXTRACT_DIRECTORIES="${QT4_TARGET_DIRECTORIES}
+		doc/src/images
+		src
+		include
+		tools"
+
+	qt4-build_pkg_setup
+}
+
+src_prepare() {
+	qt4-build_src_prepare
+
+	# Array mapping USE flags to subdirs
+	local flags_subdirs_map=(
+		'dbus'
+		'declarative:declarative'
+		'multimedia:spectrum'
+		'opengl:boxes|glhypnotizer'
+		'openvg'
+		'webkit:browser'
+		'xmlpatterns'
+	)
+
+	# Disable unwanted examples/demos
+	for flag in "${flags_subdirs_map[@]}"; do
+		if ! use ${flag%:*}; then
+			einfo "Disabling ${flag%:*} examples"
+			sed -i -e "/SUBDIRS += ${flag%:*}/d" \
+				examples/examples.pro || die
+
+			if [[ ${flag} == *:* ]]; then
+				einfo "Disabling ${flag%:*} demos"
+				sed -i -re "/SUBDIRS \+= demos_(${flag#*:})/d" \
+					demos/demos.pro || die
+			fi
+		fi
+	done
+
+	if ! use qt3support; then
+		einfo "Disabling qt3support examples"
+		sed -i -e '/QT_CONFIG, qt3support/d' \
+			examples/graphicsview/graphicsview.pro || die
+	fi
+}
+
+src_configure() {
+	myconf+="
+		$(qt_use dbus)
+		$(qt_use declarative)
+		$(qt_use multimedia)
+		$(qt_use opengl)
+		$(qt_use openvg)
+		$(qt_use qt3support)
+		$(qt_use webkit)
+		$(qt_use xmlpatterns)"
+
+	qt4-build_src_configure
+}
+
+src_install() {
+	insinto "${QTDOCDIR#${EPREFIX}}"/src
+	doins -r doc/src/images
+
+	qt4-build_src_install
+}