bumping, adds py3 support too

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x33ED3FD25AFC78BA)

2 files changed, 71 insertions, 1 deletions

diff --git a/dev-python/eventlet/ChangeLog b/dev-python/eventlet/ChangeLog
index 2b496c9e4dc9..b52514ff1a89 100644
--- a/dev-python/eventlet/ChangeLog
+++ b/dev-python/eventlet/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/eventlet
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/eventlet/ChangeLog,v 1.10 2015/02/01 16:30:37 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/eventlet/ChangeLog,v 1.11 2015/02/26 04:40:14 prometheanfire Exp $
+
+*eventlet-0.17.1 (26 Feb 2015)
+
+  26 Feb 2015; Matthew Thode <prometheanfire@gentoo.org>
+  +eventlet-0.17.1.ebuild:
+  bumping, adds py3 support too
 
   01 Feb 2015; Manuel Rüger <mrueg@gentoo.org> -eventlet-0.12.1-r1.ebuild,
   -eventlet-0.9.16.ebuild:
diff --git a/dev-python/eventlet/eventlet-0.17.1.ebuild b/dev-python/eventlet/eventlet-0.17.1.ebuild
new file mode 100644
index 000000000000..3858942453f6
--- /dev/null
+++ b/dev-python/eventlet/eventlet-0.17.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/eventlet/eventlet-0.17.1.ebuild,v 1.1 2015/02/26 04:40:14 prometheanfire Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
+
+inherit distutils-r1
+
+DESCRIPTION="Highly concurrent networking library"
+HOMEPAGE="http://pypi.python.org/pypi/eventlet https://github.com/eventlet/eventlet/"
+SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/greenlet-0.3[${PYTHON_USEDEP}]"
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/python-docs-2.7.6-r1:2.7 )
+	test? ( ${RDEPEND}
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" doc/conf.py || die
+	fi
+
+	if use test; then
+		sed -i '/This is a Python 3 module/d' eventlet/green/http/__init__.py || die
+		sed -i 's/^import/from OpenSSL import/g' eventlet/green/OpenSSL/__init__.py || die
+		sed -i 's/^from version/from OpenSSL.version/' eventlet/green/OpenSSL/__init__.py || die
+		sed -i 's/TEST_TIMEOUT = 1/TEST_TIMEOUT = 10/' tests/__init__.py || die
+	fi
+
+	# Prevent file collisions from teestsuite
+	sed -e "s:'tests', :'tests', 'tests.*', :" -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# https://github.com/eventlet/eventlet/issues/152
+	use doc && emake -C doc html
+}
+
+python_test() {
+	# Several errors 1 failure
+	# https://github.com/eventlet/eventlet/issues/151
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}