Version bump. This fixes bug #549862. Thanks to Sebastian Pipping for the report.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 215AD14D)

2 files changed, 73 insertions, 1 deletions

diff --git a/dev-libs/libisoburn/ChangeLog b/dev-libs/libisoburn/ChangeLog
index 2545720172aa..9606e1799d4b 100644
--- a/dev-libs/libisoburn/ChangeLog
+++ b/dev-libs/libisoburn/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libisoburn
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libisoburn/ChangeLog,v 1.151 2015/04/03 10:28:01 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libisoburn/ChangeLog,v 1.152 2015/05/22 17:54:46 billie Exp $
+
+*libisoburn-1.4.0 (22 May 2015)
+
+  22 May 2015; Daniel Pielmeier <billie@gentoo.org> +libisoburn-1.4.0.ebuild:
+  Version bump. This fixes bug #549862. Thanks to Sebastian Pipping for the
+  report.
 
   03 Apr 2015; Daniel Pielmeier <billie@gentoo.org> -libisoburn-1.3.4.ebuild:
   Remove old.
diff --git a/dev-libs/libisoburn/libisoburn-1.4.0.ebuild b/dev-libs/libisoburn/libisoburn-1.4.0.ebuild
new file mode 100644
index 000000000000..3c47ba90d408
--- /dev/null
+++ b/dev-libs/libisoburn/libisoburn-1.4.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libisoburn/libisoburn-1.4.0.ebuild,v 1.1 2015/05/22 17:54:46 billie Exp $
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Enables creation and expansion of ISO-9660 filesystems on all CD/DVD media supported by libburn"
+HOMEPAGE="http://libburnia-project.org/"
+SRC_URI="http://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="acl cdio debug external-filters external-filters-setuid frontend-optional
+	launch-frontend launch-frontend-setuid libedit readline static-libs xattr zlib"
+
+REQUIRED_USE="frontend-optional? ( || ( launch-frontend launch-frontend-setuid ) )"
+
+RDEPEND=">=dev-libs/libburn-1.4.0
+	>=dev-libs/libisofs-1.4.0
+	readline? ( sys-libs/readline )
+	!readline? ( libedit? ( dev-libs/libedit ) )
+	acl? ( virtual/acl )
+	xattr? ( sys-apps/attr )
+	zlib? ( sys-libs/zlib )
+	cdio? ( >=dev-libs/libcdio-0.83 )
+	launch-frontend? ( dev-lang/tcl:0 dev-lang/tk:0 )
+	launch-frontend-setuid? ( dev-lang/tcl:0 dev-lang/tk:0 )
+	frontend-optional? ( dev-tcltk/bwidget )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	econf \
+	$(use_enable static-libs static) \
+	$(use_enable readline libreadline) \
+	$(usex readline --disable-libedit $(use_enable libedit)) \
+	$(use_enable acl libacl) \
+	$(use_enable xattr) \
+	$(use_enable zlib) \
+	--disable-libjte \
+	$(use_enable cdio libcdio) \
+	$(use_enable external-filters) \
+	$(use_enable external-filters-setuid) \
+	$(use_enable launch-frontend) \
+	$(use_enable launch-frontend-setuid) \
+	--disable-ldconfig-at-install \
+	--enable-pkg-check-modules \
+	$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	dodoc CONTRIBUTORS doc/{comments,*.wiki,startup_file.txt}
+
+	docinto frontend
+	dodoc frontend/README-tcltk
+	docinto xorriso
+	dodoc xorriso/{changelog.txt,README_gnu_xorriso}
+	docinto xorriso/html
+
+	prune_libtool_files --all
+}