Version bump. Switch to EAPI=5.

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 64 insertions, 1 deletions

diff --git a/dev-libs/gmime/ChangeLog b/dev-libs/gmime/ChangeLog
index e76f38f85d0a..94110ccfb37d 100644
--- a/dev-libs/gmime/ChangeLog
+++ b/dev-libs/gmime/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/gmime
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v 1.213 2012/11/24 18:46:43 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v 1.214 2012/11/24 18:54:51 eva Exp $
+
+*gmime-2.6.12 (24 Nov 2012)
+
+  24 Nov 2012; Gilles Dartiguelongue <eva@gentoo.org> +gmime-2.6.12.ebuild:
+  Version bump. Switch to EAPI=5.
 
 *gmime-2.4.33 (24 Nov 2012)
 
diff --git a/dev-libs/gmime/gmime-2.6.12.ebuild b/dev-libs/gmime/gmime-2.6.12.ebuild
new file mode 100644
index 000000000000..206f2a8b420d
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.6.12.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/gmime-2.6.12.ebuild,v 1.1 2012/11/24 18:54:51 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 eutils mono
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME."
+HOMEPAGE="http://spruce.sourceforge.net/gmime/ http://developer.gnome.org/gmime/stable/"
+
+SLOT="2.6"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc mono static-libs"
+
+RDEPEND=">=dev-libs/glib-2.18:2
+	sys-libs/zlib
+	>=app-crypt/gpgme-1.1.6
+	mono? (
+		dev-lang/mono
+		>=dev-dotnet/glib-sharp-2.4.0:2 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	mono? ( dev-dotnet/gtk-sharp-gapi:2 )
+"
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog NEWS PORTING README TODO"
+	G2CONF="${G2CONF}
+		--enable-cryptography
+		--disable-strict-parser
+		$(use_enable mono)
+		$(use_enable static-libs static)"
+	gnome2_src_configure
+}
+
+src_compile() {
+	MONO_PATH="${S}" gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	GACUTIL_FLAGS="/root '${ED}/usr/$(get_libdir)' /gacdir '${EPREFIX}/usr/$(get_libdir)' /package ${PN}" \
+		gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc docs/tutorial/html/*
+	fi
+}