Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 files changed, 53 insertions, 0 deletions

diff --git a/app-text/zathura-pdf-mupdf/zathura-pdf-mupdf-0.2.6.ebuild b/app-text/zathura-pdf-mupdf/zathura-pdf-mupdf-0.2.6.ebuild
new file mode 100644
index 000000000000..e6bac27648e5
--- /dev/null
+++ b/app-text/zathura-pdf-mupdf/zathura-pdf-mupdf-0.2.6.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/zathura-pdf-mupdf/zathura-pdf-mupdf-0.2.6.ebuild,v 1.1 2014/04/04 21:25:02 ssuominen Exp $
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+[[ ${PV} == 9999* ]] && inherit git-2
+
+DESCRIPTION="PDF plug-in for zathura"
+HOMEPAGE="http://pwmt.org/projects/zathura/"
+if ! [[ ${PV} == 9999* ]]; then
+SRC_URI="http://pwmt.org/projects/zathura/plugins/download/${P}.tar.gz"
+fi
+EGIT_REPO_URI="git://git.pwmt.org/${PN}.git"
+EGIT_BRANCH="mupdf-git"
+
+LICENSE="ZLIB"
+SLOT="0"
+if ! [[ ${PV} == 9999* ]]; then
+KEYWORDS="~amd64 ~x86"
+else
+KEYWORDS=""
+fi
+IUSE=""
+
+RDEPEND="!app-text/zathura-pdf-poppler
+	>=app-text/mupdf-1.3:=
+	>=app-text/zathura-0.2.7
+	media-libs/jbig2dec:=
+	media-libs/openjpeg:2=
+	virtual/jpeg:0
+	x11-libs/cairo:="
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_setup() {
+	myzathuraconf=(
+		CC="$(tc-getCC)"
+		LD="$(tc-getLD)"
+		VERBOSE=1
+		DESTDIR="${D}"
+	)
+}
+
+src_compile() {
+	emake "${myzathuraconf[@]}"
+}
+
+src_install() {
+	emake "${myzathuraconf[@]}" install
+	dodoc AUTHORS
+}