Add a snapshot compatible with evolution-3.6, bug #448902. Fix compatibility with automake-1.13, bug #467596.

(Portage version: 2.2.0_alpha176/cvs/Linux x86_64, signed Manifest commit with key C6085806)

1 files changed, 68 insertions, 0 deletions

diff --git a/app-office/planner/planner-0.14.6_p20130520.ebuild b/app-office/planner/planner-0.14.6_p20130520.ebuild
new file mode 100644
index 000000000000..07e25dab917d
--- /dev/null
+++ b/app-office/planner/planner-0.14.6_p20130520.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/planner/planner-0.14.6_p20130520.ebuild,v 1.1 2013/05/20 11:12:14 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_{6,7} )
+
+inherit autotools eutils gnome2 python-single-r1
+
+DESCRIPTION="Project manager for Gnome"
+HOMEPAGE="http://live.gnome.org/Planner/"
+SRC_URI="http://dev.gentoo.org/~eva/distfiles/${PN}/${P}.tar.xz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+IUSE="eds examples python"
+
+RDEPEND="
+	>=dev-libs/glib-2.6:2
+	>=x11-libs/gtk+-2.14:2
+	>=gnome-base/libgnomecanvas-2.10
+	>=gnome-base/libgnomeui-2.10
+	>=gnome-base/libglade-2.4:2.0
+	>=gnome-base/gconf-2.6:2
+	>=dev-libs/libxml2-2.6.27:2
+	>=dev-libs/libxslt-1.1.23
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygtk-2.6:2[${PYTHON_USEDEP}] )
+	eds? (
+		>=gnome-extra/evolution-data-server-3.6
+		>=mail-client/evolution-3.6 )"
+
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35.5
+	gnome-base/gnome-common
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${PN}-0.14.6"
+
+src_configure() {
+	# FIXME: disable eds backend for now, it fails, upstream bug #654005
+	gnome2_src_configure \
+		$(use_enable python) \
+		$(use_enable python python-plugin) \
+		$(use_enable eds) \
+		--disable-eds-backend \
+		--with-database=no \
+		--disable-update-mimedb
+		#$(use_enable eds eds-backend)
+}
+
+src_install() {
+	DOCS="AUTHORS COPYING ChangeLog NEWS README"
+	gnome2_src_install \
+		sqldocdir="\$(datadir)/doc/${PF}" \
+		sampledir="\$(datadir)/doc/${PF}/examples"
+
+	if ! use examples; then
+		rm -rf "${D}/usr/share/doc/${PF}/examples"
+	fi
+}