Version bump.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 59 insertions, 1 deletions

diff --git a/app-misc/pax-utils/ChangeLog b/app-misc/pax-utils/ChangeLog
index c43805d36ca4..e37410a8ec8d 100644
--- a/app-misc/pax-utils/ChangeLog
+++ b/app-misc/pax-utils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/pax-utils
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/pax-utils/ChangeLog,v 1.182 2015/07/13 09:15:47 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/pax-utils/ChangeLog,v 1.183 2015/07/20 04:15:55 vapier Exp $
+
+*pax-utils-1.0.5 (20 Jul 2015)
+
+  20 Jul 2015; Mike Frysinger <vapier@gentoo.org> +pax-utils-1.0.5.ebuild:
+  Version bump.
 
 *pax-utils-1.0.4 (13 Jul 2015)
 
diff --git a/app-misc/pax-utils/pax-utils-1.0.5.ebuild b/app-misc/pax-utils/pax-utils-1.0.5.ebuild
new file mode 100644
index 000000000000..951c10ffee78
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.0.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/pax-utils/pax-utils-1.0.5.ebuild,v 1.1 2015/07/20 04:15:55 vapier Exp $
+
+EAPI="4"
+
+inherit eutils toolchain-funcs unpacker
+
+DESCRIPTION="ELF related utils for ELF 32/64 binaries that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/pax-utils-${PV}.tar.xz
+	http://dev.gentoo.org/~solar/pax/pax-utils-${PV}.tar.xz
+	http://dev.gentoo.org/~vapier/dist/pax-utils-${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="caps python"
+
+RDEPEND="caps? ( sys-libs/libcap )
+	python? ( dev-python/pyelftools )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+_emake() {
+	emake \
+		USE_CAP=$(usex caps) \
+		USE_PYTHON=$(usex python) \
+		"$@"
+}
+
+src_configure() {
+	# Avoid slow configure+gnulib+make if on an up-to-date Linux system
+	if use prefix || ! use kernel_linux || \
+	   has_version '<sys-libs/glibc-2.10'
+	then
+		econf $(use_with caps) $(use_with python)
+	else
+		tc-export CC
+	fi
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake check
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+}