Version bump to 2.44, migrate to python-r1; fixes bug #506232, reported by Frank Krömmelbein.

(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

2 files changed, 81 insertions, 1 deletions

diff --git a/app-misc/fslint/ChangeLog b/app-misc/fslint/ChangeLog
index bf57b5fbd23d..047e28134d3b 100644
--- a/app-misc/fslint/ChangeLog
+++ b/app-misc/fslint/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/fslint
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/fslint/ChangeLog,v 1.6 2014/01/16 17:50:42 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/fslint/ChangeLog,v 1.7 2014/03/30 18:25:02 tomwij Exp $
+
+*fslint-2.44 (30 Mar 2014)
+
+  30 Mar 2014; Tom Wijsman <TomWij@gentoo.org> +fslint-2.44.ebuild:
+  Version bump to 2.44, migrate to python-r1; fixes bug #506232, reported by
+  Frank Krömmelbein.
 
   16 Jan 2014; Jeroen Roovers <jer@gentoo.org> fslint-2.42.ebuild,
   metadata.xml:
diff --git a/app-misc/fslint/fslint-2.44.ebuild b/app-misc/fslint/fslint-2.44.ebuild
new file mode 100644
index 000000000000..e41f1f5c9619
--- /dev/null
+++ b/app-misc/fslint/fslint-2.44.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/fslint/fslint-2.44.ebuild,v 1.1 2014/03/30 18:25:02 tomwij Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_6 python2_7 )
+
+inherit eutils python-r1
+
+DESCRIPTION="A utility to find various forms of lint on a filesystem."
+HOMEPAGE="http://www.pixelbeat.org/fslint/"
+SRC_URI="http://www.pixelbeat.org/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="nls"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	dev-util/glade:*[python,${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext:* )"
+
+src_prepare() {
+	# Change some paths to make ${PN}-gui run when installed in /usr/bin.
+	sed -e "s:^liblocation=.*$:liblocation='${EROOT}usr/share/${PN}' #Gentoo:" \
+		-e "s:^locale_base=.*$:locale_base=None #Gentoo:" \
+		-i ${PN}-gui || die
+}
+
+src_install() {
+	share=/usr/share/${PN}
+
+	insinto ${share}
+	doins ${PN}{.glade,.gladep,_icon.png}
+
+	exeinto ${share}/${PN}
+	doexe ${PN}/find*
+	doexe ${PN}/${PN}
+	doexe ${PN}/zipdir
+
+	exeinto ${share}/${PN}/fstool/
+	doexe ${PN}/fstool/*
+
+	exeinto ${share}/${PN}/supprt/
+	doexe ${PN}/supprt/{fslver,getffl,getffp,getfpf,md5sum_approx}
+
+	exeinto ${share}/${PN}/supprt/rmlint
+	doexe ${PN}/supprt/rmlint/*
+
+	dobin ${PN}-gui
+
+	doicon ${PN}_icon.png
+	domenu ${PN}.desktop
+
+	dodoc doc/{FAQ,NEWS,README,TODO}
+	doman man/${PN}{.1,-gui.1}
+
+	if use nls ; then
+		cd po
+		emake DESTDIR="${D}" install
+	fi
+
+	# Fix Python shebangs.
+	python_replicate_script "${ED}"${share}/${PN}/fstool/dupwaste
+	python_replicate_script "${ED}"${share}/${PN}/supprt/md5sum_approx
+	python_replicate_script "${ED}"${share}/${PN}/supprt/rmlint/merge_hardlinks
+	python_replicate_script "${ED}"${share}/${PN}/supprt/rmlint/fixdup
+	python_replicate_script "${ED}"/usr/bin/${PN}-gui
+}