Version bump

(Portage version: 2.1.9.42/cvs/Linux x86_64)

2 files changed, 66 insertions, 1 deletions

diff --git a/app-misc/gtypist/ChangeLog b/app-misc/gtypist/ChangeLog
index 1c76939cd4f2..f6a51a787c6e 100644
--- a/app-misc/gtypist/ChangeLog
+++ b/app-misc/gtypist/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/gtypist
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v 1.22 2011/04/22 23:20:45 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v 1.23 2011/05/10 08:39:59 xmw Exp $
+
+*gtypist-2.8.5 (10 May 2011)
+
+  10 May 2011; Michael Weber <xmw@gentoo.org> +gtypist-2.8.5.ebuild:
+  Version bump (thanks to Nick Bowler, bug 365893)
 
   22 Apr 2011; Tim Harder <radhermit@gentoo.org> -gtypist-2.7.ebuild,
   -gtypist-2.7-r1.ebuild, -files/gtypist-2.7-xemacs-compat.patch,
diff --git a/app-misc/gtypist/gtypist-2.8.5.ebuild b/app-misc/gtypist/gtypist-2.8.5.ebuild
new file mode 100644
index 000000000000..4ec180577c14
--- /dev/null
+++ b/app-misc/gtypist/gtypist-2.8.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/gtypist-2.8.5.ebuild,v 1.1 2011/05/10 08:39:59 xmw Exp $
+
+EAPI=2
+
+inherit eutils elisp-common
+
+DESCRIPTION="Universal typing tutor"
+HOMEPAGE="http://www.gnu.org/software/gtypist/"
+SRC_URI="mirror://gnu/gtypist/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="nls emacs xemacs"
+
+DEPEND=">=sys-libs/ncurses-5.2
+	emacs? ( virtual/emacs )
+	xemacs? ( !emacs? ( app-editors/xemacs app-xemacs/fsf-compat ) )"
+
+RDEPEND="${DEPEND}"
+
+SITEFILE=50${PN}-gentoo.el
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.8.3-xemacs-compat.patch
+}
+
+src_configure() {
+	local lispdir=""
+	if use emacs; then
+		lispdir="${SITELISP}/${PN}"
+		einfo "Configuring to build with GNU Emacs support"
+	elif use xemacs; then
+		lispdir="/usr/lib/xemacs/site-packages/lisp/${PN}"
+		einfo "Configuring to build with XEmacs support"
+	fi
+
+	econf $(use_enable nls) \
+		EMACS=$(usev emacs || usev xemacs || echo no) \
+		--with-lispdir="${lispdir}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}