Version bump for Gnome 3.10, drop old

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 files changed, 45 insertions, 0 deletions

diff --git a/app-misc/geoclue/geoclue-2.0.0.ebuild b/app-misc/geoclue/geoclue-2.0.0.ebuild
new file mode 100644
index 000000000000..4bbd63ff141e
--- /dev/null
+++ b/app-misc/geoclue/geoclue-2.0.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/geoclue/geoclue-2.0.0.ebuild,v 1.1 2013/12/24 15:35:15 pacho Exp $
+
+EAPI="5"
+
+inherit gnome2 user versionator
+
+MY_PV=$(get_version_component_range 1-2)
+DESCRIPTION="A geoinformation D-Bus service"
+HOMEPAGE="http://freedesktop.org/wiki/Software/GeoClue"
+SRC_URI="http://www.freedesktop.org/software/${PN}/releases/${MY_PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+IUSE="server"
+
+RDEPEND="
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/json-glib-0.14
+	net-libs/libsoup:2.4
+	sys-apps/dbus
+	server? ( >=dev-libs/geoip-1.5.1 )
+	!<sci-geosciences/geocode-glib-3.10.0
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+
+RESTRICT="test"
+
+src_configure() {
+	# debug only affects CFLAGS
+	gnome2_src_configure \
+		--with-dbus-service-user=geoclue \
+		$(use_enable server geoip-server)
+}
+
+pkg_preinst() {
+	enewgroup geoclue
+	enewuser geoclue -1 -1 /var/lib/geoclue geoclue
+}