app-emulation/cloud-init: add virtual/logger dependency—fixes bug #511384

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 92FEA28B)

3 files changed, 95 insertions, 1 deletions

diff --git a/app-emulation/cloud-init/ChangeLog b/app-emulation/cloud-init/ChangeLog
index a1b289aa7e7b..00b096c06b44 100644
--- a/app-emulation/cloud-init/ChangeLog
+++ b/app-emulation/cloud-init/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/cloud-init
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/cloud-init/ChangeLog,v 1.10 2014/08/06 06:44:38 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/cloud-init/ChangeLog,v 1.11 2014/08/24 23:53:40 alunduil Exp $
+
+*cloud-init-0.7.5-r2 (24 Aug 2014)
+
+  24 Aug 2014; Alex Brandt <alunduil@gentoo.org> +cloud-init-0.7.5-r2.ebuild,
+  metadata.xml:
+  Add virtual/logger dependency. Fixes bug #511384
 
   06 Aug 2014; Patrick Lauer <patrick@gentoo.org> cloud-init-0.7.5-r1.ebuild:
   Make description more repoman-happy
diff --git a/app-emulation/cloud-init/cloud-init-0.7.5-r2.ebuild b/app-emulation/cloud-init/cloud-init-0.7.5-r2.ebuild
new file mode 100644
index 000000000000..7cefd7b88ca0
--- /dev/null
+++ b/app-emulation/cloud-init/cloud-init-0.7.5-r2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/cloud-init/cloud-init-0.7.5-r2.ebuild,v 1.1 2014/08/24 23:53:40 alunduil Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=TRUE
+
+inherit distutils-r1 eutils multilib systemd
+
+DESCRIPTION="Cloud instance initialization"
+HOMEPAGE="http://launchpad.net/cloud-init"
+SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+CDEPEND="
+	dev-python/cheetah[${PYTHON_USEDEP}]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	dev-python/oauth[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		${CDEPEND}
+		>=dev-python/httpretty-0.7.1[${PYTHON_USEDEP}]
+		dev-python/mocker[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pep8[${PYTHON_USEDEP}]
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+		dev-python/pylint[${PYTHON_USEDEP}]
+		sys-apps/iproute2
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	virtual/logger
+"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}"/${P}-tests-exclude.patch
+	)
+
+	distutils-r1_python_prepare_all
+
+	# Skip SmartOS tests since they don't generally apply and don't skip based
+	# on environment.  Documented in bug #511384.
+	rm tests/unittests/test_datasource/test_smartos.py
+}
+
+python_test() {
+	# These tests are not broken but expect to locate an installed exe file
+	# other than where a gentoo system installs it;  (/bin/ip sought in /sbin)
+	# See cloudinit/sources/DataSourceOpenNebula.py for possible patching
+	sed \
+		-e 's:test_hostname:_&:' \
+		-e 's:test_network_interfaces:_&:' \
+		-i tests/unittests/test_datasource/test_opennebula.py
+
+	emake test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doinitd "${S}"/sysvinit/gentoo/cloud-config
+	doinitd "${S}"/sysvinit/gentoo/cloud-final
+	doinitd "${S}"/sysvinit/gentoo/cloud-init
+	doinitd "${S}"/sysvinit/gentoo/cloud-init-local
+
+	systemd_dounit "${S}"/systemd/cloud-config.service
+	systemd_dounit "${S}"/systemd/cloud-config.target
+	systemd_dounit "${S}"/systemd/cloud-final.service
+	systemd_dounit "${S}"/systemd/cloud-init-local.service
+	systemd_dounit "${S}"/systemd/cloud-init.service
+}
diff --git a/app-emulation/cloud-init/metadata.xml b/app-emulation/cloud-init/metadata.xml
index 20820d92906c..75cf7f9d2d6d 100644
--- a/app-emulation/cloud-init/metadata.xml
+++ b/app-emulation/cloud-init/metadata.xml
@@ -6,6 +6,10 @@
     <email>prometheanfire@gentoo.org</email>
     <name>Matthew Thode</name>
   </maintainer>
+  <maintainer>
+	<email>alunduil@gentoo.org</email>
+	<name>Alex Brandt</name>
+  </maintainer>
   <longdescription lang="en">
     Package provides configuration and customization of cloud instance.
   </longdescription>