Fix bug #508876 - Bump to scite 3.4.1 thanks to Ervin Peters

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2EDD52403B68AF47)

2 files changed, 93 insertions, 1 deletions

diff --git a/app-editors/scite/ChangeLog b/app-editors/scite/ChangeLog
index 5b5b144f22f8..0523bf8f5086 100644
--- a/app-editors/scite/ChangeLog
+++ b/app-editors/scite/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/scite
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.170 2014/02/16 12:10:42 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.171 2014/05/01 20:24:54 swift Exp $
+
+*scite-3.4.1 (01 May 2014)
+
+  01 May 2014; Sven Vermeulen <swift@gentoo.org> +scite-3.4.1.ebuild:
+  Bump for 3.4.1, thanks to Ervin Peters (bug #508876)
 
   16 Feb 2014; Markos Chandras <hwoarang@gentoo.org> metadata.xml:
   Add Ervin Peters <ervin.peters@ervnet.de> as maintainer
diff --git a/app-editors/scite/scite-3.4.1.ebuild b/app-editors/scite/scite-3.4.1.ebuild
new file mode 100644
index 000000000000..69c9635af62d
--- /dev/null
+++ b/app-editors/scite/scite-3.4.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-3.4.1.ebuild,v 1.1 2014/05/01 20:24:54 swift Exp $
+
+EAPI="4"
+
+inherit toolchain-funcs eutils
+
+MY_PV=${PV//./}
+DESCRIPTION="A very powerful editor for programmers"
+HOMEPAGE="http://www.scintilla.org/SciTE.html"
+SRC_URI="mirror://sourceforge/scintilla/${PN}${MY_PV}.tgz"
+
+LICENSE="HPND lua? ( MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="lua"
+
+RDEPEND="dev-libs/glib
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/gdk-pixbuf
+	x11-libs/pango
+	lua? ( >=dev-lang/lua-5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	>=sys-apps/sed-4"
+
+S="${WORKDIR}/${PN}/gtk"
+
+src_prepare() {
+	cd "${WORKDIR}/scintilla/gtk"
+	sed -i makefile \
+		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
+		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
+		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
+		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
+		-e "s#-Os##" \
+		|| die "error patching makefile"
+
+	cd "${WORKDIR}/scite/gtk"
+	sed -i makefile \
+		-e "s#-rdynamic#-rdynamic ${LDFLAGS}#" \
+		|| die "error patching makefile"
+
+	cd "${S}"
+	sed -i makefile \
+		-e 's#usr/local#usr#g' \
+		-e 's#/gnome/apps/Applications#/applications#' \
+		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
+		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
+		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
+		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
+		-e 's#${D}##' \
+		-e 's#-g root#-g 0#' \
+		-e "s#-Os##" \
+		|| die "error patching makefile"
+	cd "${WORKDIR}"
+	epatch "${FILESDIR}/${PN}-3.0.1-no-lua.patch"
+}
+
+src_compile() {
+	emake -C ../../scintilla/gtk AR="$(tc-getAR)"
+	if use lua; then
+		emake
+	else
+		emake NO_LUA=1
+	fi
+}
+
+src_install() {
+	dodir /usr/bin
+	dodir /usr/share/{pixmaps,applications}
+
+	emake prefix="${ED}/usr" install
+
+	# we have to keep this because otherwise it'll break upgrading
+	mv "${ED}/usr/bin/SciTE" "${ED}/usr/bin/scite" || die
+	dosym /usr/bin/scite /usr/bin/SciTE
+
+	# replace .desktop file with our own working version
+	rm -f "${ED}/usr/share/applications/SciTE.desktop"
+	domenu "${FILESDIR}/scite.desktop"
+
+	doman ../doc/scite.1
+	dodoc ../README
+}