Change dev-libs/openssl[-bindist] to dev-libs/openssl[bindist=], as xca detects automatically if openssl supports ec or not, while not having explicit way to enable/disable. bug#462510, thanks to wmatusiak

(Portage version: 2.2.0_alpha168/cvs/Linux x86_64, signed Manifest commit with key BF20DC51)

2 files changed, 61 insertions, 1 deletions

diff --git a/app-crypt/xca/ChangeLog b/app-crypt/xca/ChangeLog
index aed000239f1c..1862a53978a2 100644
--- a/app-crypt/xca/ChangeLog
+++ b/app-crypt/xca/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-crypt/xca
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/xca/ChangeLog,v 1.38 2013/03/02 19:16:54 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/xca/ChangeLog,v 1.39 2013/03/22 20:19:24 alonbl Exp $
+
+*xca-0.9.3-r1 (22 Mar 2013)
+
+  22 Mar 2013; Alon Bar-Lev <alonbl@gentoo.org> +xca-0.9.3-r1.ebuild:
+  Change dev-libs/openssl[-bindist] to dev-libs/openssl[bindist=], as xca
+  detects automatically if openssl supports ec or not, while not having explicit
+  way to enable/disable. bug#462510, thanks to wmatusiak
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> xca-0.9.0.ebuild,
   xca-0.9.1.ebuild, xca-0.9.3.ebuild:
diff --git a/app-crypt/xca/xca-0.9.3-r1.ebuild b/app-crypt/xca/xca-0.9.3-r1.ebuild
new file mode 100644
index 000000000000..456c2abfe62f
--- /dev/null
+++ b/app-crypt/xca/xca-0.9.3-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/xca/xca-0.9.3-r1.ebuild,v 1.1 2013/03/22 20:19:24 alonbl Exp $
+
+EAPI="4"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A GUI to OpenSSL, RSA public keys, certificates, signing requests and revokation lists"
+HOMEPAGE="http://www.hohnstaedt.de/xca.html"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc bindist"
+
+RDEPEND=">=dev-libs/openssl-0.9.8[bindist=]
+	dev-qt/qtgui:4"
+DEPEND="${RDEPEND}
+	doc? ( app-text/linuxdoc-tools )"
+
+src_prepare() {
+	# http://sourceforge.net/tracker/index.php?func=detail&aid=1800298&group_id=62274&atid=500028
+	epatch "${FILESDIR}"/${PN}-0.9.0-qt_detection.patch
+	epatch "${FILESDIR}"/${PN}-0.9.1-ldflags.patch
+	epatch "${FILESDIR}"/${P}-desktop.patch
+}
+
+src_configure() {
+	local LINUXDOC
+	use doc || LINUXDOC='touch $@ && true'
+
+	QTDIR="${EPREFIX}/usr" \
+		STRIP="true" \
+		LINUXDOC="${LINUXDOC}" \
+		CC="$(tc-getCXX)" \
+		LD="$(tc-getLD)" \
+		CFLAGS="${CXXFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		prefix="${EPREFIX}/usr" \
+		docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		./configure || die	"configure failed"
+}
+
+src_install() {
+	emake destdir="${D}" mandir="share/man" install
+
+	dodoc AUTHORS
+
+	insinto /etc/xca
+	doins misc/*.txt
+}