Fixed ldap keyserver - bug #104112. Added static build back- bug #104059

(Portage version: 2.0.51.22-r2)

6 files changed, 256 insertions, 16 deletions

diff --git a/app-crypt/gnupg/ChangeLog b/app-crypt/gnupg/ChangeLog
index 3ba325655115..700620e0fc08 100644
--- a/app-crypt/gnupg/ChangeLog
+++ b/app-crypt/gnupg/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for app-crypt/gnupg
 # Copyright 2002-2005 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.127 2005/08/16 10:55:19 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.128 2005/08/31 11:20:27 dragonheart Exp $
+
+*gnupg-1.4.2-r2 (31 Aug 2005)
+
+  31 Aug 2005; Daniel Black <dragonheart@gentoo.org>
+  +files/gnupg-1.4.2-keyserver.patch, gnupg-1.4.2-r1.ebuild,
+  +gnupg-1.4.2-r2.ebuild:
+  Fixed ldap keyserver - bug #104112 thanks to Peter Hyman. Added static build
+  back - bug #104059 thanks to Venkat Manakkal
 
   16 Aug 2005; Daniel Black <dragonheart@gentoo.org> gnupg-1.4.1.ebuild,
   gnupg-1.4.1-r1.ebuild, gnupg-1.4.2-r1.ebuild, -gnupg-1.9.15-r1.ebuild:
diff --git a/app-crypt/gnupg/Manifest b/app-crypt/gnupg/Manifest
index 094871af9ead..4b84a9836352 100644
--- a/app-crypt/gnupg/Manifest
+++ b/app-crypt/gnupg/Manifest
@@ -1,15 +1,19 @@
+MD5 83679e04da772721130866b531ea0da2 gnupg-1.9.18.ebuild 3211
 MD5 c716059f4407cf6cfd1e778e86106521 ChangeLog 20941
+MD5 1e5af0d32a41a81910c020de579b2fb5 gnupg-1.4.2-r1.ebuild 6232
+MD5 cab71046870fb2ca973dfc39b1154fee gnupg-1.4.2-r2.ebuild 6461
+MD5 921f00a83ce6b1d77190396b4456f05f gnupg-1.2.6.ebuild 3800
+MD5 b507ee36c7487372de42cc9dab034370 metadata.xml 481
+MD5 fb2459cc632ade0377625d0768292e92 gnupg-1.4.1.ebuild 6195
+MD5 b0bb6593b289c825ed2428ac396967ba gnupg-1.4.1-r1.ebuild 6281
+MD5 7247c8f0379977f0a3dd13568bf283c7 files/digest-gnupg-1.9.18 66
 MD5 c3a43a1e5da266ef33222f721e05fd63 files/digest-gnupg-1.2.6 117
-MD5 4b92f911e900cfd1a37439bd19412f5d files/digest-gnupg-1.4.1 190
-MD5 4b92f911e900cfd1a37439bd19412f5d files/digest-gnupg-1.4.1-r1 190
 MD5 331553038bdcb95cc843c60b01b73925 files/digest-gnupg-1.4.2-r1 190
-MD5 7247c8f0379977f0a3dd13568bf283c7 files/digest-gnupg-1.9.18 66
 MD5 dd317d852aed29e96c5a542f00d0766e files/gnupg-1.2.6-ppc64.patch 454
+MD5 331553038bdcb95cc843c60b01b73925 files/digest-gnupg-1.4.2-r2 190
+MD5 c23d51ccf048f10b5e8b10b45570c13a files/gnupg-1.4.1.diff 370
+MD5 ee3a4487eadfb9858f32adde3554394c files/gnupg-1.4.2-keyserver.patch 389
+MD5 4b92f911e900cfd1a37439bd19412f5d files/digest-gnupg-1.4.1 190
+MD5 4b92f911e900cfd1a37439bd19412f5d files/digest-gnupg-1.4.1-r1 190
 MD5 494103ac08d870d8a9c1ed0b83c4ae35 files/gnupg-1.4.1-selftest.patch 1180
 MD5 552b43a0705ea006efa282b7d5645143 files/gnupg-1.4.2-selftest.patch 1358
-MD5 921f00a83ce6b1d77190396b4456f05f gnupg-1.2.6.ebuild 3800
-MD5 b0bb6593b289c825ed2428ac396967ba gnupg-1.4.1-r1.ebuild 6281
-MD5 fb2459cc632ade0377625d0768292e92 gnupg-1.4.1.ebuild 6195
-MD5 6cc0b66f6b9713b9d467c184724dadc7 gnupg-1.4.2-r1.ebuild 6171
-MD5 83679e04da772721130866b531ea0da2 gnupg-1.9.18.ebuild 3211
-MD5 b507ee36c7487372de42cc9dab034370 metadata.xml 481
diff --git a/app-crypt/gnupg/files/digest-gnupg-1.4.2-r2 b/app-crypt/gnupg/files/digest-gnupg-1.4.2-r2
new file mode 100644
index 000000000000..e9f46e0a9867
--- /dev/null
+++ b/app-crypt/gnupg/files/digest-gnupg-1.4.2-r2
@@ -0,0 +1,3 @@
+MD5 c7afd50c7d01fcfada229326b3958404 gnupg-1.4.2.tar.bz2 2891177
+MD5 9dc3bc086824a8c7a331f35e09a3e57f idea.c.gz 5216
+MD5 4e7e9d224879e5a3e01cb2ab4c719559 gnupg-1.4.0-ecc0.1.6.diff.bz2 16703
diff --git a/app-crypt/gnupg/files/gnupg-1.4.2-keyserver.patch b/app-crypt/gnupg/files/gnupg-1.4.2-keyserver.patch
new file mode 100644
index 000000000000..8590f401bfa8
--- /dev/null
+++ b/app-crypt/gnupg/files/gnupg-1.4.2-keyserver.patch
@@ -0,0 +1,13 @@
+--- g10/keyserver.c.orig	2005-08-31 13:17:20.000000000 +1000
++++ g10/keyserver.c	2005-08-31 13:18:19.000000000 +1000
+@@ -860,7 +860,9 @@
+ static const char *
+ keyserver_typemap(const char *type)
+ {
+-  if(strcmp(type,"ldaps")==0)
++  if(strcmp(type,"ldap")==0)
++    return "ldap";
++  else if(strcmp(type,"ldaps")==0)
+     return "ldap";
+   else if(curl_can_handle(type))
+     return "curl";
diff --git a/app-crypt/gnupg/gnupg-1.4.2-r1.ebuild b/app-crypt/gnupg/gnupg-1.4.2-r1.ebuild
index e243573a2114..9ed3710396c7 100644
--- a/app-crypt/gnupg/gnupg-1.4.2-r1.ebuild
+++ b/app-crypt/gnupg/gnupg-1.4.2-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2005 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-1.4.2-r1.ebuild,v 1.3 2005/08/16 10:55:19 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-1.4.2-r1.ebuild,v 1.4 2005/08/31 11:20:27 dragonheart Exp $
 
 inherit eutils flag-o-matic
 
@@ -25,7 +25,7 @@ IUSE="bzip2 caps curl ecc idea ldap nls readline selinux smartcard usb zlib X"
 #			zlib? ( sys-libs/zlib )
 #		)
 
-RDEPEND="
+COMMON_DEPEND="
 	ldap? ( net-nds/openldap )
 	bzip2? ( app-arch/bzip2 )
 	zlib? ( sys-libs/zlib )
@@ -35,13 +35,13 @@ RDEPEND="
 	virtual/mta
 	readline? ( sys-libs/readline )
 	smartcard? ( dev-libs/libusb )
-	selinux? ( sec-policy/selinux-gnupg )
 	usb? ( dev-libs/libusb )"
 
-RDEPEND="${RDEPEND}
-	X? ( || ( media-gfx/xloadimage media-gfx/xli ) )"
+RDEPEND="${COMMON_DEPEND}
+	X? ( || ( media-gfx/xloadimage media-gfx/xli ) )
+	selinux? ( sec-policy/selinux-gnupg )"
 
-DEPEND="${RDEPEND}
+DEPEND="${COMMON_DEPEND}
 	dev-lang/perl"
 
 src_unpack() {
@@ -70,6 +70,9 @@ src_unpack() {
 	cd ${S}
 	sed -i -e 's:PIC:__PIC__:' mpi/i386/mpih-{add,sub}1.S intl/relocatable.c
 	sed -i -e 's:if PIC:ifdef __PIC__:' mpi/sparc32v8/mpih-mul{1,2}.S
+
+	# Fix ldap helper
+	epatch ${FILESDIR}/${P}-keyserver.patch
 }
 
 src_compile() {
diff --git a/app-crypt/gnupg/gnupg-1.4.2-r2.ebuild b/app-crypt/gnupg/gnupg-1.4.2-r2.ebuild
new file mode 100644
index 000000000000..091060aaa6e3
--- /dev/null
+++ b/app-crypt/gnupg/gnupg-1.4.2-r2.ebuild
@@ -0,0 +1,209 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-1.4.2-r2.ebuild,v 1.1 2005/08/31 11:20:27 dragonheart Exp $
+
+inherit eutils flag-o-matic
+
+ECCVER=0.1.6
+ECCVER_GNUPG=1.4.0
+
+DESCRIPTION="The GNU Privacy Guard, a GPL pgp replacement"
+HOMEPAGE="http://www.gnupg.org/"
+SRC_URI="mirror://gnupg/gnupg/${P}.tar.bz2
+	idea? ( ftp://ftp.gnupg.dk/pub/contrib-dk/idea.c.gz )
+	ecc? ( http://alumnes.eps.udl.es/%7Ed4372211/src/${PN}-${ECCVER_GNUPG}-ecc${ECCVER}.diff.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc-macos ~ppc64 ~s390 ~sparc ~x86"
+IUSE="bzip2 caps curl ecc idea ldap nls readline selinux smartcard static usb zlib X"
+
+COMMON_DEPEND="
+	ldap? ( net-nds/openldap )
+	bzip2? ( app-arch/bzip2 )
+	zlib? ( sys-libs/zlib )
+	nls? ( sys-devel/gettext )
+	curl? ( net-misc/curl )
+	virtual/libc
+	virtual/mta
+	readline? ( sys-libs/readline )
+	smartcard? ( dev-libs/libusb )
+	usb? ( dev-libs/libusb )"
+
+RDEPEND="!static? (
+		${COMMON_DEPEND}
+		X? ( || ( media-gfx/xloadimage media-gfx/xli ) )
+	)
+	selinux? ( sec-policy/selinux-gnupg )"
+
+DEPEND="${COMMON_DEPEND}
+	dev-lang/perl"
+
+src_unpack() {
+	unpack ${A}
+
+	# Jari's patch to boost iterated key setup by factor of 128
+	# EPATCH_OPTS="-p1 -d ${S}" epatch ${FILESDIR}/gnupg-1.4.1.diff	
+
+	if use idea; then
+		ewarn "Please read http://www.gnupg.org/why-not-idea.html"
+		mv ${WORKDIR}/idea.c ${S}/cipher/idea.c || \
+			ewarn "failed to insert IDEA module"
+	fi
+
+	if use ecc; then
+		# this trickery is because the only reject in the 1.4.0 patch is the
+		# version number!
+		local eccpatch=${WORKDIR}/${PN}-${ECCVER_GNUPG}-ecc${ECCVER}.diff
+		if [ "${ECCVER_GNUPG}" != "${PV}" ]; then
+			einfo "Tweaking PV in ECC patch"
+			sed -i "s/ VERSION='${ECCVER_GNUPG}/ VERSION='${PV}/g" $eccpatch
+		fi
+		EPATCH_OPTS="-p1 -d ${S}" epatch $eccpatch
+	fi
+
+	# maketest fix
+	epatch ${FILESDIR}/${P}-selftest.patch
+
+	cd ${S}
+	# keyserver fix
+	epatch ${FILESDIR}/${P}-keyserver.patch
+
+	# Fix PIC definitions
+	sed -i -e 's:PIC:__PIC__:' mpi/i386/mpih-{add,sub}1.S intl/relocatable.c
+	sed -i -e 's:if PIC:ifdef __PIC__:' mpi/sparc32v8/mpih-mul{1,2}.S
+}
+
+src_compile() {
+	# Certain sparc32 machines seem to have trouble building correctly with
+	# -mcpu enabled.  While this is not a gnupg problem, it is a temporary
+	# fix until the gcc problem can be tracked down.
+	if [ "${ARCH}" == "sparc" ] && [ "${PROFILE_ARCH}" == "sparc" ]; then
+		filter-flags -mcpu=supersparc -mcpu=v8 -mcpu=v7
+	fi
+
+	# 'USE=static' support was requested in #29299
+	use static &&append-ldflags -static
+
+	# Still needed?
+	# Bug #6387, --enable-m-guard causes bus error on sparcs
+	use sparc || myconf="${myconf} --enable-m-guard"
+
+	use ppc-macos || append-ldflags -Wl,-z,now
+
+	# configure doesn't trean --disable-asm correctly
+	use x86 && myconf="${myconf} --enable-asm"
+
+	# fix compile problem on ppc64
+	use ppc64 && myconf="${myconf} --disable-asm"
+
+	econf \
+		$(use_enable ldap) \
+		--enable-mailto \
+		--enable-hkp \
+		--enable-finger \
+		$(use_with !zlib included-zlib) \
+		$(use_with curl libcurl /usr) \
+		$(use_enable nls) \
+		$(use_enable bzip2) \
+		$(use_enable smartcard card-support) \
+		$(use_enable selinux selinux-support) \
+		$(use_with caps capabilities) \
+		$(use_with readline) \
+		$(use_with usb libusb /usr) \
+		$(use_enable static) \
+		$(use_enable X photo-viewers) \
+		--enable-static-rnd=linux \
+		--libexecdir=/usr/libexec \
+		--enable-sha512 \
+		${myconf} || die
+	# this is because it will run some tests directly
+	gnupg_fixcheckperms
+	emake || die
+}
+
+src_install() {
+	gnupg_fixcheckperms
+	make DESTDIR=${D} install || die
+
+	# caps support makes life easier
+	use caps || fperms u+s,go-r /usr/bin/gpg
+
+	# keep the documentation in /usr/share/doc/...
+	rm -rf "${D}/usr/share/gnupg/FAQ" "${D}/usr/share/gnupg/faq.html"
+
+	dodoc AUTHORS BUGS ChangeLog INSTALL NEWS PROJECTS README THANKS \
+		TODO VERSION doc/{FAQ,HACKING,DETAILS,ChangeLog,OpenPGP,faq.raw}
+
+	docinto sgml
+	dodoc doc/*.sgml
+
+	dohtml doc/faq.html
+
+	# Remove collissions
+	if use ppc-macos; then
+		rm ${D}/usr/lib/charset.alias ${D}/usr/share/locale/locale.alias
+	fi
+}
+
+gnupg_fixcheckperms() {
+	# GnuPG does weird things for testing that it build correctly
+	# as we as for the additional tests. It WILL fail with perms 770 :-(.
+	# See bug #80044
+	if has userpriv ${FEATURES}; then
+		einfo "Fixing permissions in check directory"
+		chown -R portage:portage ${S}/checks
+		chmod -R ugo+rw ${S}/checks
+		chmod ugo+rw ${S}/checks
+	fi
+}
+
+src_test() {
+	gnupg_fixcheckperms
+	einfo "Running tests"
+	emake check
+	ret=$?
+	if [ $ret -ne 0 ]; then
+		die "Some tests failed! Please report to the Gentoo Bugzilla"
+	fi
+}
+
+pkg_postinst() {
+	if ! use caps; then
+		einfo "gpg is installed suid root to make use of protected memory space"
+		einfo "This is needed in order to have a secure place to store your"
+		einfo "passphrases, etc. at runtime but may make some sysadmins nervous."
+	fi
+	echo
+	if use idea; then
+		einfo "-----------------------------------------------------------------------------------"
+		einfo "IDEA"
+		ewarn "you have compiled ${PN} with support for the IDEA algorithm, this code"
+		ewarn "is distributed under the GPL in countries where it is permitted to do so"
+		ewarn "by law."
+		einfo
+		einfo "Please read http://www.gnupg.org/why-not-idea.html for more information."
+		einfo
+		ewarn "If you are in a country where the IDEA algorithm is patented, you are permitted"
+		ewarn "to use it at no cost for 'non revenue generating data transfer between private"
+		ewarn "individuals'."
+		einfo
+		einfo "Countries where the patent applies are listed here"
+		einfo "http://www.mediacrypt.com/_contents/10_idea/101030_ea_pi.asp"
+		einfo
+		einfo "Further information and other licenses are availble from http://www.mediacrypt.com/"
+		einfo "-----------------------------------------------------------------------------------"
+	fi
+	if use ecc; then
+		einfo
+		ewarn "The elliptical curves patch is experimental"
+		einfo "Further info available at http://alumnes.eps.udl.es/%7Ed4372211/index.en.html"
+	fi
+	if use caps; then
+		einfo
+		ewarn "Capabilities code is experimental"
+	fi
+	einfo
+	einfo "See http://www.gentoo.org/doc/en/gnupg-user.xml for documentation on gnupg"
+	einfo
+}