Add the new gnome-3.2 on-screen keyboard system from the gnome overlay.

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

3 files changed, 108 insertions, 0 deletions

diff --git a/app-accessibility/caribou/ChangeLog b/app-accessibility/caribou/ChangeLog
new file mode 100644
index 000000000000..15dc36cf5981
--- /dev/null
+++ b/app-accessibility/caribou/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for app-accessibility/caribou
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/caribou/ChangeLog,v 1.1 2011/11/05 04:52:19 tetromino Exp $
+
+*caribou-0.4.1 (05 Nov 2011)
+
+  05 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +caribou-0.4.1.ebuild, +metadata.xml:
+  Add the new gnome-3.2 on-screen keyboard system from the gnome overlay.
+
diff --git a/app-accessibility/caribou/caribou-0.4.1.ebuild b/app-accessibility/caribou/caribou-0.4.1.ebuild
new file mode 100644
index 000000000000..f01ccfc959f0
--- /dev/null
+++ b/app-accessibility/caribou/caribou-0.4.1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/caribou/caribou-0.4.1.ebuild,v 1.1 2011/11/05 04:52:19 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="2:2.4"
+PYTHON_USE_WITH="xml"
+
+inherit gnome2 python
+
+DESCRIPTION="Input assistive technology intended for switch and pointer users"
+HOMEPAGE="https://live.gnome.org/Caribou"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND=">=dev-python/pygobject-2.90.3:3
+	>=x11-libs/gtk+-3.0.0:3[introspection]
+	x11-libs/gtk+:2
+	>=dev-libs/gobject-introspection-0.10.7
+	dev-libs/libgee:0
+	dev-libs/libxml2
+	>=media-libs/clutter-1.5.11:1.0[introspection]
+	x11-libs/libX11
+	x11-libs/libxklavier
+	x11-libs/libXtst"
+# gsettings-desktop-schemas is needed for the 'toolkit-accessibility' key
+# pyatspi-2.1.90 needed to run caribou if pygobject:3 is installed
+# librsvg needed to load svg images in css styles
+RDEPEND="${COMMON_DEPEND}
+	dev-python/dbus-python
+	>=dev-python/pyatspi-2.1.90
+	gnome-base/gconf[introspection]
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/librsvg:2
+	sys-apps/dbus"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35.5
+	app-text/gnome-doc-utils"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-static
+		--disable-schemas-compile
+		--enable-gtk3-module
+		--enable-gtk2-module
+		VALAC=$(type -P true)"
+	# vala is not needed for tarball builds, but configure checks for it...
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	# delete custom PYTHONPATH, useless on Gentoo and potential bug source
+	sed -e '/export PYTHONPATH=.*python/ d' \
+		-i bin/{antler-keyboard,caribou,caribou-preferences}.in ||
+		die "sed failed"
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	python_convert_shebangs -r 2 "${ED}"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_mod_optimize caribou
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup caribou
+}
diff --git a/app-accessibility/caribou/metadata.xml b/app-accessibility/caribou/metadata.xml
new file mode 100644
index 000000000000..4d1f3599c74e
--- /dev/null
+++ b/app-accessibility/caribou/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>gnome</herd>
+<longdescription lang="en">
+Caribou is a text entry and UI navigation application being developed as an
+alternative to the Gnome On-screen Keyboard. The overarching goal for Caribou
+is to create a usable solution for people whose primary way of accessing a
+computer is a switch device. The initial goal is to make an in-place on-screen
+keyboard suitable for people who can use a mouse but not a hardware keyboard.
+</longdescription>
+</pkgmetadata>