version bump

(Portage version: 2.1.4.4)

2 files changed, 122 insertions, 2 deletions

diff --git a/media-sound/snd/ChangeLog b/media-sound/snd/ChangeLog
index 0daf97030375..1b83561d4998 100644
--- a/media-sound/snd/ChangeLog
+++ b/media-sound/snd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/snd
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/snd/ChangeLog,v 1.38 2007/07/29 17:24:11 angelos Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/snd/ChangeLog,v 1.39 2008/03/07 17:46:48 aballier Exp $
+
+*snd-9.7 (07 Mar 2008)
+
+  07 Mar 2008; Alexis Ballier <aballier@gentoo.org> +snd-9.7.ebuild:
+  version bump
 
   29 Jul 2007; Christoph Mende <angelos@gentoo.org> snd-9.1.ebuild:
   Stable on amd64 wrt bug #187007
diff --git a/media-sound/snd/snd-9.7.ebuild b/media-sound/snd/snd-9.7.ebuild
new file mode 100644
index 000000000000..656c44f31081
--- /dev/null
+++ b/media-sound/snd/snd-9.7.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/snd/snd-9.7.ebuild,v 1.1 2008/03/07 17:46:48 aballier Exp $
+
+inherit multilib eutils
+
+DESCRIPTION="Snd is a sound editor"
+HOMEPAGE="http://ccrma.stanford.edu/software/snd/"
+SRC_URI="ftp://ccrma-ftp.stanford.edu/pub/Lisp/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="as-is"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa cairo esd fam fftw gsl gtk guile jack ladspa motif nls opengl oss ruby xpm"
+
+RDEPEND="media-libs/audiofile
+	motif? ( x11-libs/openmotif )
+	alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	fam? ( virtual/fam )
+	fftw? ( sci-libs/fftw )
+	gsl? ( >=sci-libs/gsl-0.8 )
+	gtk? ( >=x11-libs/gtk+-2
+		opengl? ( x11-libs/gtkglext )
+		cairo? ( x11-libs/cairo ) )
+	guile? ( >=dev-scheme/guile-1.3.4 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	ladspa? ( media-libs/ladspa-sdk )
+	nls? ( sys-devel/gettext )
+	opengl? ( virtual/opengl )
+	ruby? ( virtual/ruby )
+	xpm? ( x11-libs/libXpm )"
+
+pkg_setup() {
+	if ! use gtk && ! use motif; then
+		ewarn "Warning: no graphic toolkit selected (gtk or motif)."
+		ewarn "Upstream suggests to enable one of the toolkits (or both)"
+		ewarn "or only the command line utilities will be helpful."
+	fi
+}
+
+src_compile() {
+	local myconf
+
+	if use opengl; then
+		if use guile; then
+			myconf="${myconf} --with-gl"
+		else
+			myconf="${myconf} --with-just-gl"
+		fi
+	else
+		myconf="${myconf} --without-gl"
+	fi
+
+	econf \
+		$(use_with alsa) \
+		$(use_with oss) \
+		$(use_with esd) \
+		$(use_with fam) \
+		$(use_with fftw) \
+		$(use_with gsl) \
+		$(use_with gtk) \
+		$(use_with guile) \
+		$(use_with jack) \
+		$(use_with ladspa) \
+		$(use_with motif) \
+		$(use_enable nls) \
+		$(use_with ruby) \
+		$(use_with cairo) \
+		$(use_with xpm) \
+		--with-float-samples \
+		${myconf} || die
+
+	emake snd || die "emake snd failed"
+
+	# compiling command-line programs. See bug #112695
+	# do not compile ruby extensions for command line programs
+	# those fail to compile
+	if use ruby; then
+		econf \
+			$(use_with alsa) \
+			$(use_with esd) \
+			$(use_with fam) \
+			$(use_with fftw) \
+			$(use_with gsl) \
+			$(use_with gtk) \
+			$(use_with guile) \
+			$(use_with jack) \
+			$(use_with ladspa) \
+			$(use_with motif) \
+			$(use_enable nls) \
+			$(use_with xpm) \
+			--without-ruby \
+			--with-float-samples \
+			${myconf} || die
+	fi
+
+	for i in sndrecord sndinfo audinfo sndplay; do
+		emake ${i} || die "make ${i} failed"
+	done
+}
+
+src_install () {
+	dobin snd
+	dobin sndplay
+	dobin sndrecord
+	dobin sndinfo
+	dobin audinfo
+
+	insinto /usr/$(get_libdir)/snd/scheme
+	doins *.scm
+
+	dodoc README.Snd HISTORY.Snd TODO.Snd Snd.ad
+	dohtml -r *.html *.png tutorial
+}