Version bump for bug fixes

(Portage version: 2.2_rc1/cvs/Linux 2.6.25-gentoo-r6 i686)

2 files changed, 96 insertions, 1 deletions

diff --git a/dev-libs/glib/ChangeLog b/dev-libs/glib/ChangeLog
index 17c5d0d9dd7c..ada695612eb7 100644
--- a/dev-libs/glib/ChangeLog
+++ b/dev-libs/glib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.325 2008/07/05 10:11:04 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.326 2008/07/12 11:35:59 leio Exp $
+
+*glib-2.16.4 (12 Jul 2008)
+
+  12 Jul 2008; <leio@gentoo.org> +glib-2.16.4.ebuild:
+  Version bump for bug fixes
 
   05 Jul 2008; Tobias Scherbaum <dertobi123@gentoo.org>
   glib-2.16.3-r1.ebuild:
diff --git a/dev-libs/glib/glib-2.16.4.ebuild b/dev-libs/glib/glib-2.16.4.ebuild
new file mode 100644
index 000000000000..727f5819064f
--- /dev/null
+++ b/dev-libs/glib/glib-2.16.4.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.16.4.ebuild,v 1.1 2008/07/12 11:35:59 leio Exp $
+
+inherit gnome.org libtool eutils flag-o-matic
+
+DESCRIPTION="The GLib library of C routines"
+HOMEPAGE="http://www.gtk.org/"
+
+LICENSE="LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="debug doc fam hardened selinux xattr"
+
+RDEPEND="virtual/libc
+		 virtual/libiconv
+		 xattr? ( sys-apps/attr )
+		 fam? ( virtual/fam )"
+DEPEND="${RDEPEND}
+		>=dev-util/pkgconfig-0.16
+		>=sys-devel/gettext-0.11
+		doc?	(
+					>=dev-libs/libxslt-1.0
+					>=dev-util/gtk-doc-1.8
+					~app-text/docbook-xml-dtd-4.1.2
+				)"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	if use ppc64 && use hardened ; then
+		replace-flags -O[2-3] -O1
+		epatch "${FILESDIR}/glib-2.6.3-testglib-ssp.patch"
+	fi
+
+	if use ia64 ; then
+		# Only apply for < 4.1
+		local major=$(gcc-major-version)
+		local minor=$(gcc-minor-version)
+		if (( major < 4 || ( major == 4 && minor == 0 ) )); then
+			epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
+		fi
+	fi
+
+	sed -e "s/MATCH_LIMIT_RECURSION=10000000/MATCH_LIMIT_RECURSION=8192/g" \
+		-i "${S}/glib/pcre/Makefile.in" "${S}/glib/pcre/Makefile.am"
+
+	# GNOME bug #538836, fix gio test failure on various arches
+	sed -i -e 's:|\\<g_atomic_int\\|:|\\<g_atomic_int\\|\\<g_atomic_pointer_get\\|:' \
+		"${S}/gio/pltcheck.sh"
+
+	# Fix gmodule issues on fbsd; bug #184301
+	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch
+
+	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
+}
+
+src_compile() {
+	local myconf
+
+	epunt_cxx
+
+	# Building with --disable-debug highly unrecommended.  It will build glib in
+	# an unusable form as it disables some commonly used API.  Please do not
+	# convert this to the use_enable form, as it results in a broken build.
+	# -- compnerd (3/27/06)
+	use debug && myconf="--enable-debug"
+
+	# always build static libs, see #153807
+	econf ${myconf}                 \
+		  $(use_enable xattr)       \
+		  $(use_enable doc man)     \
+		  $(use_enable doc gtk-doc) \
+		  $(use_enable fam)         \
+		  $(use_enable selinux)     \
+		  --enable-static           \
+		  --with-threads=posix || die "configure failed"
+
+	emake || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "Installation failed"
+
+	# Do not install charset.alias even if generated, leave it to libiconv
+	rm -f "${D}/usr/lib/charset.alias"
+
+	dodoc AUTHORS ChangeLog* NEWS* README
+}