Version bump. Replace shipped minilzo (bug #515278). Work around parallel make issue in src_test().

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 78 insertions, 2 deletions

diff --git a/net-analyzer/nfdump/ChangeLog b/net-analyzer/nfdump/ChangeLog
index aa3ffada5366..b338d06e663a 100644
--- a/net-analyzer/nfdump/ChangeLog
+++ b/net-analyzer/nfdump/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/nfdump
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nfdump/ChangeLog,v 1.35 2013/08/14 12:48:31 jer Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nfdump/ChangeLog,v 1.36 2014/06/27 03:14:26 jer Exp $
+
+*nfdump-1.6.12 (27 Jun 2014)
+
+  27 Jun 2014; Jeroen Roovers <jer@gentoo.org> +nfdump-1.6.12.ebuild:
+  Version bump. Replace shipped minilzo (bug #515278). Work around parallel
+  make issue in src_test().
 
 *nfdump-1.6.10_p1 (14 Aug 2013)
 
diff --git a/net-analyzer/nfdump/nfdump-1.6.12.ebuild b/net-analyzer/nfdump/nfdump-1.6.12.ebuild
new file mode 100644
index 000000000000..1e0f74099d7f
--- /dev/null
+++ b/net-analyzer/nfdump/nfdump-1.6.12.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nfdump/nfdump-1.6.12.ebuild,v 1.1 2014/06/27 03:14:26 jer Exp $
+
+EAPI=5
+inherit autotools eutils
+
+MY_P="${P/_/}"
+DESCRIPTION="A set of tools to collect and process netflow data"
+HOMEPAGE="http://nfdump.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/nfdump/${MY_P}.tar.gz
+	http://www.oberhumer.com/opensource/lzo/download/minilzo-2.07.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="compat15 debug ftconv nfprofile nftrack readpcap sflow"
+
+CDEPEND="
+	ftconv? ( sys-libs/zlib net-analyzer/flow-tools )
+	nfprofile? ( net-analyzer/rrdtool )
+	nftrack? ( net-analyzer/rrdtool )
+	readpcap? ( net-libs/libpcap )
+"
+DEPEND="
+	${CDEPEND}
+	sys-devel/flex
+	virtual/yacc
+"
+RDEPEND="
+	${CDEPEND}
+	dev-lang/perl
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# bug #515278
+	cp "${WORKDIR}"/minilzo-2.07/*.{c,h} "${S}"/bin || die
+
+	if use ftconv; then
+		sed -e '/ftbuild.h/d' -i bin/ft2nfdump.c || die
+		sed \
+			-e 's:lib\(/ftlib.h\):include\1:' \
+			-e 's:libft.a:libft.so:' \
+			\-i configure.in || die
+	fi
+	sed -i bin/Makefile.am -e '/^AM_CFLAGS/d' || die
+	eautoreconf
+}
+
+src_configure() {
+	# --without-ftconf is not handled well #322201
+	econf \
+		$(use ftconv && echo "--enable-ftconv --with-ftpath=/usr") \
+		$(use nfprofile && echo --enable-nfprofile) \
+		$(use nftrack && echo --enable-nftrack) \
+		$(use_enable compat15) \
+		$(use_enable debug devel) \
+		$(use_enable readpcap) \
+		$(use_enable sflow)
+}
+
+src_test() {
+	emake -j1 check
+}