x11-plugins/wmxres/wmxres-1.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit toolchain-funcs

DESCRIPTION="Dock application to select your display mode among those possible"
HOMEPAGE="http://yalla.free.fr/wn"
SRC_URI="http://yalla.free.fr/wn/${PN}-1.1-0.tar.gz"

LICENSE="GPL-1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

RDEPEND="x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXpm
	x11-libs/libXxf86vm"
DEPEND="${RDEPEND}
	x11-base/xorg-proto
	x11-libs/libXxf86dga"

S="${WORKDIR}/${PN}.app"

PATCHES=( "${FILESDIR}"/${PN}-debian-1.1-1.2.patch )

src_prepare() {
	default
	sed -e "s:-g -c -O2:${CFLAGS} -c:" \
		-e "s:\tcc :\t $(tc-getCC) \$(LDFLAGS) :g" \
		-i Makefile || die "sed failed"
}

src_compile() {
	emake INCDIR="-I${EPREFIX}/usr/include" LIBDIR="-L${EPREFIX}/usr/$(get_libdir)"
}

src_install() {
	dobin ${PN}/${PN}
	doman ${PN}.1
}