blob: 8c1179ebaaea7eb80e9099dcc45f306d2723d49d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit meson python-single-r1 vala udev xdg
DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
HOMEPAGE="https://fwupd.org"
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~loong ppc64 ~riscv x86"
IUSE="amdgpu amt +archive bash-completion bluetooth cbor elogind fastboot flashrom gnutls gtk-doc +gusb introspection logitech lzma minimal modemmanager nvme policykit spi +sqlite synaptics systemd test test-full tpm uefi"
REQUIRED_USE="${PYTHON_REQUIRED_USE}
^^ ( elogind minimal systemd )
fastboot? ( gusb )
logitech? ( gusb )
minimal? ( !introspection )
modemmanager? ( gusb )
spi? ( lzma )
synaptics? ( gnutls )
test? ( archive gusb )
test-full? ( test )
uefi? ( gnutls )
"
RESTRICT="!test? ( test )"
BDEPEND="$(vala_depend)
$(python_gen_cond_dep '
dev-python/jinja[${PYTHON_USEDEP}]
')
>=dev-util/meson-0.60.0
virtual/pkgconfig
gtk-doc? (
$(python_gen_cond_dep '
>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
')
>=dev-util/gi-docgen-2021.1
)
bash-completion? ( >=app-shells/bash-completion-2.0 )
introspection? ( dev-libs/gobject-introspection )
test? (
net-libs/gnutls[tools]
test-full? ( dev-util/umockdev )
)
"
COMMON_DEPEND="${PYTHON_DEPS}
>=app-arch/gcab-1.0
app-arch/xz-utils
>=dev-libs/glib-2.68:2
>=dev-libs/json-glib-1.6.0
>=dev-libs/libgudev-232:=
>=dev-libs/libjcat-0.1.4[gpg,pkcs7]
>=dev-libs/libxmlb-0.3.6:=[introspection?]
$(python_gen_cond_dep '
dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
')
>=net-misc/curl-7.62.0
archive? ( app-arch/libarchive:= )
cbor? ( >=dev-libs/libcbor-0.7.0:= )
elogind? ( >=sys-auth/elogind-211 )
flashrom? ( >=sys-apps/flashrom-1.2-r3 )
gnutls? ( >=net-libs/gnutls-3.6.0 )
gusb? ( >=dev-libs/libgusb-0.3.8[introspection?] )
logitech? ( dev-libs/protobuf-c:= )
lzma? ( app-arch/xz-utils )
modemmanager? ( net-misc/modemmanager[mbim,qmi] )
policykit? ( >=sys-auth/polkit-0.114 )
sqlite? ( dev-db/sqlite )
systemd? ( >=sys-apps/systemd-211 )
tpm? ( app-crypt/tpm2-tss:= )
uefi? (
sys-apps/fwupd-efi
sys-boot/efibootmgr
sys-fs/udisks
sys-libs/efivar
)
"
RDEPEND="
${COMMON_DEPEND}
sys-apps/dbus
"
DEPEND="
${COMMON_DEPEND}
x11-libs/pango[introspection]
amdgpu? ( sys-kernel/linux-headers )
"
PATCHES=(
"${FILESDIR}"/${PN}-1.9.6-fragile_tests.patch
)
pkg_pretend() {
if [[ ${MERGE_TYPE} != buildonly ]]; then
if use test-full && has sandbox ${FEATURES}; then
ewarn "Certain ${PN} tests are fragile with sandboxing enabled,"
ewarn "see https://github.com/fwupd/fwupd/issues/1414."
ewarn "When in doubt, emerge ${PN} with USE=-test-full."
fi
fi
}
src_prepare() {
default
vala_setup
sed -e "/install_dir.*'doc'/s/doc/gtk-doc/" \
-i docs/meson.build || die
python_fix_shebang "${S}"/contrib/*.py
}
src_configure() {
local plugins=(
-Dplugin_gpio="enabled"
$(meson_feature amdgpu plugin_amdgpu)
$(meson_feature amt plugin_intel_me)
$(meson_feature fastboot plugin_fastboot)
$(meson_feature flashrom plugin_flashrom)
$(meson_feature gusb plugin_uf2)
$(meson_feature logitech plugin_logitech_bulkcontroller)
$(meson_feature modemmanager plugin_modem_manager)
$(meson_feature nvme plugin_nvme)
$(meson_use spi plugin_intel_spi)
$(meson_feature synaptics plugin_synaptics_mst)
$(meson_feature synaptics plugin_synaptics_rmi)
$(meson_feature tpm plugin_tpm)
$(meson_feature uefi plugin_uefi_capsule)
$(meson_use uefi plugin_uefi_capsule_splash)
$(meson_feature uefi plugin_uefi_pk)
)
if use ppc64 || use riscv ; then
plugins+=( -Dplugin_msr="disabled" )
fi
local emesonargs=(
--localstatedir "${EPREFIX}"/var
-Dbuild="$(usex minimal standalone all)"
-Dconsolekit="disabled"
-Dcurl="enabled"
-Defi_binary="false"
-Dman="true"
-Dsupported_build="enabled"
-Dudevdir="${EPREFIX}$(get_udevdir)"
$(meson_feature archive libarchive)
$(meson_use bash-completion bash_completion)
$(meson_feature bluetooth bluez)
$(meson_feature cbor)
$(meson_feature elogind)
$(meson_feature gnutls)
$(meson_feature gtk-doc docs)
$(meson_feature gusb)
$(meson_feature lzma)
$(meson_feature introspection)
$(meson_feature policykit polkit)
$(meson_feature sqlite)
$(meson_feature systemd)
$(meson_use test tests)
$(meson_use test-full)
${plugins[@]}
)
use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
export CACHE_DIRECTORY="${T}"
meson_src_configure
}
src_test() {
LC_ALL="C" meson_src_test
}
src_install() {
meson_src_install
if ! use minimal ; then
newinitd "${FILESDIR}"/${PN}-r2 ${PN}
fi
if use test; then
# Preventing tests from being installed in the first place is a moving target,
# just axe them all afterwards.
rm -rf "${ED}"/etc/fwupd/remotes.d/fwupd-tests.conf \
"${ED}"/usr/libexec/installed-tests \
"${ED}"/usr/share/fwupd/device-tests \
"${ED}"/usr/share/fwupd/host-emulate.d/thinkpad-p1-iommu.json.gz \
"${ED}"/usr/share/installed-tests \
|| die
fi
}
pkg_postinst() {
xdg_pkg_postinst
use minimal || udev_reload
}
pkg_postrm() {
xdg_pkg_postrm
use minimal || udev_reload
}
|
GitWeb