blob: 23eb58b65043474583dbece4ecaffcd03c10d9a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit python-single-r1 flag-o-matic autotools optfeature bash-completion-r1
MY_PN="Rivet"
MY_PF=${MY_PN}-${PV}
DESCRIPTION="Rivet toolkit (Robust Independent Validation of Experiment and Theory)"
HOMEPAGE="
https://rivet.hepforge.org/
https://gitlab.com/hepcedar/rivet
"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.com/hepcedar/rivet"
else
SRC_URI="https://www.hepforge.org/archive/rivet/${MY_PF}.tar.gz -> ${P}.tar.gz"
S=${WORKDIR}/${MY_PF}
KEYWORDS="~amd64"
fi
LICENSE="GPL-3+"
SLOT="3"
IUSE="+hepmc3 hepmc2 +zlib +python"
REQUIRED_USE="
^^ ( hepmc3 hepmc2 )
python? ( ${PYTHON_REQUIRED_USE} )
"
# <sci-physics/hepmc-3.2.7 due to https://gitlab.com/hepcedar/rivet/-/issues/414
RDEPEND="
>=sci-physics/fastjet-3.4.0[plugins]
>=sci-physics/fastjet-contrib-1.048
hepmc2? ( sci-physics/hepmc:2=[-cm(-),gev(+)] )
hepmc3? ( <sci-physics/hepmc-3.2.7:3=[-cm(-),gev(+)] )
sci-libs/gsl
zlib? ( sys-libs/zlib )
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/matplotlib[${PYTHON_USEDEP}]
')
>=sci-physics/yoda-1.9.8[${PYTHON_SINGLE_USEDEP}]
<sci-physics/yoda-2[${PYTHON_SINGLE_USEDEP}]
)
!python? (
>=sci-physics/yoda-1.9.8
<sci-physics/yoda-2
)
"
DEPEND="${RDEPEND}"
BDEPEND="
app-shells/bash
python? (
$(python_gen_cond_dep '
>=dev-python/cython-0.29.24[${PYTHON_USEDEP}]
')
)
"
PATCHES=(
"${FILESDIR}"/${PN}-3.1.6-binreloc.patch
"${FILESDIR}"/${PN}-3.1.9-pythontests.patch
"${FILESDIR}"/${PN}-3.1.10-ref_cin.patch # https://gitlab.com/hepcedar/rivet/-/merge_requests/844
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
eautoreconf
}
src_configure() {
# Eigen complains about alignment (see https://gitlab.com/libeigen/eigen/-/issues/2523).
# does this affect more cpus?
replace-cpu-flags znver1 x86-64
# not posix compatible, only bash
CONFIG_SHELL=${ESYSROOT}/bin/bash econf \
$(use_with zlib zlib "${ESYSROOT}/usr") \
$(usex hepmc2 "--with-hepmc=${ESYSROOT}/usr" "") \
$(usex hepmc3 "--with-hepmc3=${ESYSROOT}/usr" "") \
--with-yoda="${ESYSROOT}/usr" \
--with-fastjet="${ESYSROOT}/usr" \
$(use_enable python pyext) \
$(usex python CYTHON="${ESYSROOT}/usr/bin/cython")
}
src_install() {
default
use python && python_optimize
find "${ED}" -name '*.la' -delete || die
if use python ; then
newbashcomp "${ED}"/etc/bash_completion.d/${PN}-completion ${PN}
bashcomp_alias ${PN} ${PN}-config \
${PN}-build \
${PN}-buildplugin \
${PN}-cmphistos \
make-plots \
${PN}-mkhtml \
${PN}-mkhtml-mpl
rm "${ED}"/etc/bash_completion.d/${PN}-completion || die
fi
}
pkg_postinstall() {
optfeature "plotting support" virtual/latex-base media-gfx/imagemagick app-text/ghostscript-gpl
}
|
GitWeb