blob: 31b62099c78340a74424a0a3a7bbdc287f791abe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Copyright 2004-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_{6,7}} )
inherit python-single-r1 xdg
DESCRIPTION="postscript font editor and converter"
HOMEPAGE="http://fontforge.github.io/"
SRC_URI="https://github.com/fontforge/fontforge/releases/download/${PV}/fontforge-${PV}.tar.gz"
LICENSE="BSD GPL-3+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="cairo truetype-debugger gif gtk jpeg png +python readline test tiff svg unicode X"
RESTRICT="!test? ( test )"
REQUIRED_USE="
cairo? ( png )
gtk? ( cairo )
python? ( ${PYTHON_REQUIRED_USE} )
test? ( png python )
"
RDEPEND="
dev-libs/glib
dev-libs/libltdl:0
dev-libs/libxml2:2=
>=media-libs/freetype-2.3.7:2=
cairo? (
>=x11-libs/cairo-1.6:0=
x11-libs/pango:0=
)
gif? ( media-libs/giflib:0= )
jpeg? ( virtual/jpeg:0 )
png? ( media-libs/libpng:0= )
tiff? ( media-libs/tiff:0= )
truetype-debugger? ( >=media-libs/freetype-2.3.8:2[fontforge,-bindist(-)] )
gtk? ( >=x11-libs/gtk+-3.10:3 )
python? ( ${PYTHON_DEPS} )
readline? ( sys-libs/readline:0= )
unicode? ( media-libs/libuninameslist:0= )
X? (
x11-libs/libX11:0=
x11-libs/libXi:0=
>=x11-libs/pango-1.10:0=[X]
)
!media-gfx/pfaedit
"
DEPEND="${RDEPEND}
X? ( x11-base/xorg-proto )
"
BDEPEND="
sys-devel/gettext
virtual/pkgconfig
"
# Needs keywording on many arches.
# zeromq? (
# >=net-libs/czmq-2.2.0:0=
# >=net-libs/zeromq-4.0.4:0=
# )
PATCHES=(
"${FILESDIR}"/20170731-gethex-unaligned.patch
"${FILESDIR}"/CVE-2020-5395.patch
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_configure() {
local myeconfargs=(
--disable-static
$(use_enable truetype-debugger freetype-debugger "${EPREFIX}/usr/include/freetype2/internal4fontforge")
$(use_enable python python-extension)
$(use_enable python python-scripting)
--enable-tile-path
$(use_with cairo)
$(use_with gif giflib)
$(use_with jpeg libjpeg)
$(use_with png libpng)
$(use_with readline libreadline)
--without-libspiro
$(use_with tiff libtiff)
$(use_with unicode libuninameslist)
$(use_with X x)
)
if use gtk; then
# broken AC_ARG_ENABLE usage
# https://bugs.gentoo.org/681550
myeconfargs+=( --enable-gdk=gdk3 )
fi
econf "${myeconfargs[@]}"
}
src_install() {
emake DESTDIR="${D}" install
docompress -x /usr/share/doc/${PF}/html
einstalldocs
find "${ED}" -name '*.la' -type f -delete || die
}
|
GitWeb