blob: 075db224501e6ff689b3b1f3f3d1bdc125137f96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
inherit distutils-r1
DESCRIPTION="Python 2 and 3 compatibility library"
HOMEPAGE="https://github.com/benjaminp/six https://pypi.org/project/six"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="doc test"
DEPEND="
doc? ( dev-python/sphinx )
test? ( >=dev-python/pytest-2.2.0[${PYTHON_USEDEP}] )"
PATCHES=(
"${FILESDIR}"/1.10.0-no-setuptools.patch
"${FILESDIR}"/1.9.0-mapping.patch
)
python_prepare_all() {
# https://bitbucket.org/gutworth/six/issues/139/
sed \
-e 's:test_assertCountEqual:_&:g' \
-e 's:test_assertRegex:_&:g' \
-e 's:test_assertRaisesRegex:_&:g' \
-i test_six.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C documentation html
}
python_test() {
py.test -v || die "Testing failed with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( documentation/_build/html/ )
distutils-r1_python_install_all
}
# Remove pkg_preinst in the next version bump
pkg_preinst() {
# https://bugs.gentoo.org/585146
cd "${HOME}" || die
_cleanup() {
local pyver=$("${PYTHON}" -c "from distutils.sysconfig import get_python_version; print(get_python_version())")
local egginfo="${ROOT%/}$(python_get_sitedir)/${P}-py${pyver}.egg-info"
if [[ -d ${egginfo} ]]; then
echo rm -r "${egginfo}"
rm -r "${egginfo}" || die "Failed to remove egg-info directory"
fi
}
python_foreach_impl _cleanup
}
|
GitWeb
