From eadd62daeb499184f038e77e5091999560554a06 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Tue, 20 Sep 2022 17:04:11 +0200
Subject: sys-devel/llvm-toolchain-symlinks: Add for LLVM 14.x
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../llvm-toolchain-symlinks-14.ebuild              | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild

(limited to 'sys-devel')

diff --git a/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild b/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild
new file mode 100644
index 000000000000..9cc42ef77e31
--- /dev/null
+++ b/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib
+
+DESCRIPTION="Symlinks to use LLVM on binutils-free system"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
+SRC_URI=""
+S=${WORKDIR}
+
+LICENSE="public-domain"
+SLOT="${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos"
+IUSE="+native-symlinks"
+
+RDEPEND="
+	sys-devel/llvm:${SLOT}
+"
+
+src_install() {
+	use native-symlinks || return
+
+	local tools=(
+		addr2line ar dlltool nm objcopy objdump ranlib readelf size
+		strings strip windres
+	)
+
+	local abi t
+	local dest=/usr/lib/llvm/${SLOT}/bin
+	dodir "${dest}"
+	for t in "${tools[@]}"; do
+		dosym "llvm-${t}" "${dest}/${t}"
+	done
+	for abi in $(get_all_abis); do
+		local abi_chost=$(get_abi_CHOST "${abi}")
+		for t in "${tools[@]}"; do
+			dosym "llvm-${t}" "${dest}/${abi_chost}-${t}"
+		done
+	done
+}
-- 
cgit v1.2.3-65-gdbad