From 2c17b93a45083759eec10a66cb8f4c0df38f6573 Mon Sep 17 00:00:00 2001
From: scardracs <marco@scardovi.com>
Date: Sun, 21 Mar 2021 14:04:57 +0100
Subject: sys-auth/fprintd: bumping to version 1.90.9

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Marco Scardovi <marco@scardovi.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 sys-auth/fprintd/Manifest              |  1 +
 sys-auth/fprintd/fprintd-1.90.9.ebuild | 76 ++++++++++++++++++++++++++++++++++
 sys-auth/fprintd/metadata.xml          | 15 +++++--
 3 files changed, 88 insertions(+), 4 deletions(-)
 create mode 100644 sys-auth/fprintd/fprintd-1.90.9.ebuild

(limited to 'sys-auth/fprintd')

diff --git a/sys-auth/fprintd/Manifest b/sys-auth/fprintd/Manifest
index 7995d31c2bec..69e1a29b01db 100644
--- a/sys-auth/fprintd/Manifest
+++ b/sys-auth/fprintd/Manifest
@@ -1,2 +1,3 @@
 DIST fprintd-0.8.1.tar.bz2 75254 BLAKE2B bf59c47c3d0186677bfd180e472e13773afebd4c3438e0e8e8cce34156df1c64c142b73d541fa876b96d4881e6967745a8c29be310dd33a509cb1863c836634e SHA512 438098fb677b742fdb279f3df85a1f2c800fce7498130c09b7408f21656ff256323b3bce4c22a2499e52c2ca7cddbc7f26033be7869939d23f9b5c436aa1f252
 DIST fprintd-v1.90.8.tar.bz2 635139 BLAKE2B 4f9e5c395c32dd5de3f5ed4d17e81c28a55de0f411deb3ccbc5d1330129be2bc8263c63c61a5e4910f74e49ebbbf508e858f5ee131eb4552e2ea8ab167bc6021 SHA512 0f38e0ce9f7c1459ba5359d0834569fe5d3f5ec3c9499d008dc39b9c869bbfa1cb293b1d96d22f9f36708f26984a1b3f0776685d628df69f1ed6db14de04a489
+DIST fprintd-v1.90.9.tar.bz2 636538 BLAKE2B 8a2150887282aae722d143ec96a9c0c3b5dd066e4cba30c41d49b6f6afe95c26c585aec2d9b074d65dd1a3efd462dae294a98965a020c4e55a8cda7c00a827bb SHA512 2b0f3e5812dd29df2b78ff6082c75981c28af71fc07e19e7eb4743842562e7d5bfc0655d5fbb66bfb167bc3087100bd0f154257ad936eab03e9e8ccc2410481f
diff --git a/sys-auth/fprintd/fprintd-1.90.9.ebuild b/sys-auth/fprintd/fprintd-1.90.9.ebuild
new file mode 100644
index 000000000000..2fd9c7e7f03d
--- /dev/null
+++ b/sys-auth/fprintd/fprintd-1.90.9.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson pam systemd
+
+DESCRIPTION="D-Bus service to access fingerprint readers"
+HOMEPAGE="https://gitlab.freedesktop.org/libfprint/fprintd"
+SRC_URI="https://gitlab.freedesktop.org/libfprint/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~x86"
+IUSE="doc pam systemd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/dbus-glib
+	dev-libs/glib:2
+	sys-auth/libfprint:2
+	sys-auth/polkit
+	pam? (
+		systemd? ( sys-apps/systemd )
+		!systemd? ( sys-auth/elogind )
+		sys-libs/pam
+	)
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	dev-lang/perl
+	doc? (
+		dev-libs/libxml2
+		dev-libs/libxslt
+		dev-util/gtk-doc
+	)
+	test? (
+		dev-python/dbusmock
+		dev-python/dbus-python
+		dev-python/pycairo
+		pam? ( sys-libs/pam_wrapper )
+	)
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.90.7_0001-add-test-feature-and-make-tests-optional.patch"
+	"${FILESDIR}/${PN}-1.90.8_0002-add-configure-option-for-libsystemd-provider.patch"
+)
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_configure() {
+		local emesonargs=(
+			$(meson_feature test)
+			$(meson_use pam)
+			-Dgtk_doc=$(usex doc true false)
+			-Dman=true
+			-Dsystemd_system_unit_dir=$(systemd_get_systemunitdir)
+			-Dpam_modules_dir=$(getpam_mod_dir)
+			-Dlibsystemd=$(usex systemd libsystemd libelogind)
+		)
+		meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	dodoc AUTHORS NEWS README TODO
+	newdoc pam/README README.pam_fprintd
+}
+
+pkg_postinst() {
+	elog "Please take a look at README.pam_fprintd for integration docs."
+}
diff --git a/sys-auth/fprintd/metadata.xml b/sys-auth/fprintd/metadata.xml
index 91a72ded097f..3479f4f0534a 100644
--- a/sys-auth/fprintd/metadata.xml
+++ b/sys-auth/fprintd/metadata.xml
@@ -1,8 +1,15 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<!-- maintainer-needed -->
-<upstream>
-	<bugs-to>https://gitlab.freedesktop.org/libfprint/fprintd/issues</bugs-to>
-</upstream>
+	<maintainer type="person" proxied="yes">
+		<email>marco@scardovi.com</email>
+		<name>Marco Scardovi</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://gitlab.freedesktop.org/libfprint/fprintd/issues</bugs-to>
+	</upstream>
 </pkgmetadata>
-- 
cgit v1.2.3-65-gdbad