From 8b7d64c5886fb5fbe4bb482f93be03e157f06fc2 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 4 Jan 2022 06:46:17 +0000
Subject: net-libs/nDPI: keep version workaround for now

Should be able to drop this in the next release.

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/nDPI/nDPI-4.0-r1.ebuild | 66 ++++++++++++++++++++++++++++++++++++++++
 net-libs/nDPI/nDPI-4.0.ebuild    | 59 -----------------------------------
 2 files changed, 66 insertions(+), 59 deletions(-)
 create mode 100644 net-libs/nDPI/nDPI-4.0-r1.ebuild
 delete mode 100644 net-libs/nDPI/nDPI-4.0.ebuild

(limited to 'net-libs/nDPI')

diff --git a/net-libs/nDPI/nDPI-4.0-r1.ebuild b/net-libs/nDPI/nDPI-4.0-r1.ebuild
new file mode 100644
index 000000000000..4be4dd426cc0
--- /dev/null
+++ b/net-libs/nDPI/nDPI-4.0-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Open Source Deep Packet Inspection Software Toolkit"
+HOMEPAGE="https://www.ntop.org/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/ntop/${PN}"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ntop/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.bz2"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0/$(ver_cut 1)"
+
+DEPEND="dev-libs/json-c:=
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	net-libs/libpcap"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${WORKDIR}"/${P}-patches/
+)
+
+# Also sent a patch upstream https://github.com/ntop/nDPI/pull/1392 for
+# AR/CC etc but doesn't apply cleanly (at all) to 4.0.
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s%^libdir\s*=\s*\${prefix}/lib\s*$%libdir     = \${prefix}/$(get_libdir)%" \
+		src/lib/Makefile.in || die
+
+	eautoreconf
+
+	# Should be able to drop in next version.
+	# Taken from autogen.sh (bug #704074):
+	sed -i \
+		-e "s/#define PACKAGE/#define NDPI_PACKAGE/g" \
+		-e "s/#define VERSION/#define NDPI_VERSION/g" \
+		configure || die
+}
+
+src_test() {
+	pushd tests || die
+
+	./do.sh || die "Failed tests"
+	./do-unit.sh || die "Failed unit tests"
+
+	popd || die
+}
+
+src_install() {
+	default
+
+	rm "${ED}/usr/$(get_libdir)"/lib${PN,,}.a || die
+}
diff --git a/net-libs/nDPI/nDPI-4.0.ebuild b/net-libs/nDPI/nDPI-4.0.ebuild
deleted file mode 100644
index 8516413b47eb..000000000000
--- a/net-libs/nDPI/nDPI-4.0.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="Open Source Deep Packet Inspection Software Toolkit"
-HOMEPAGE="https://www.ntop.org/"
-if [[ ${PV} == 9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/ntop/${PN}"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/ntop/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.bz2"
-
-	KEYWORDS="~amd64 ~x86"
-fi
-
-LICENSE="LGPL-3+"
-SLOT="0/$(ver_cut 1)"
-
-DEPEND="dev-libs/json-c:=
-	dev-libs/libgcrypt:=
-	dev-libs/libgpg-error
-	net-libs/libpcap"
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${WORKDIR}"/${P}-patches/
-)
-
-# Also sent a patch upstream https://github.com/ntop/nDPI/pull/1392 for
-# AR/CC etc but doesn't apply cleanly (at all) to 4.0.
-
-src_prepare() {
-	default
-
-	sed -i \
-		-e "s%^libdir\s*=\s*\${prefix}/lib\s*$%libdir     = \${prefix}/$(get_libdir)%" \
-		src/lib/Makefile.in || die
-
-	eautoreconf
-}
-
-src_test() {
-	pushd tests || die
-
-	./do.sh || die "Failed tests"
-	./do-unit.sh || die "Failed unit tests"
-
-	popd || die
-}
-
-src_install() {
-	default
-
-	rm "${ED}/usr/$(get_libdir)"/lib${PN,,}.a || die
-}
-- 
cgit v1.2.3-65-gdbad