From c7edb74263957a41ec1a4dd83eaf28def833efc0 Mon Sep 17 00:00:00 2001
From: Kostadin Shishmanov <kocelfc@tutanota.com>
Date: Thu, 26 Oct 2023 21:28:42 +0300
Subject: gui-apps/waypipe: add 0.8.6

Closes: https://bugs.gentoo.org/916302
Signed-off-by: Kostadin Shishmanov <kocelfc@tutanota.com>
Signed-off-by: Sam James <sam@gentoo.org>
---
 gui-apps/waypipe/Manifest             |  1 +
 gui-apps/waypipe/waypipe-0.8.6.ebuild | 71 +++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)
 create mode 100644 gui-apps/waypipe/waypipe-0.8.6.ebuild

(limited to 'gui-apps')

diff --git a/gui-apps/waypipe/Manifest b/gui-apps/waypipe/Manifest
index 2288cc924b9d..9a2abb90ffac 100644
--- a/gui-apps/waypipe/Manifest
+++ b/gui-apps/waypipe/Manifest
@@ -1 +1,2 @@
 DIST waypipe-0.8.0.tar.gz 217533 BLAKE2B a2aebb9939acafae3eb693aa8fe344ab775e8d3e9a071e7291ab15a0f9869b681156b5730e42c04401648a32ad2a67d7a3bf95ff5f38e909e9309e00b1c69381 SHA512 853d36a9779e2fcb5ac7bcca6575d456685beadd8d918ec430a57b8359867849bdcb5d9c1edcd19eb8505f06a7758e8f53ba5354daa05f99491d5a45c330eeb2
+DIST waypipe-0.8.6.tar.gz 237391 BLAKE2B 2ce67872b7cee02a46526c58026bf1f1dc15aa65ff9bb7c2293cb500a6a7d3d630e86f8356e15bf929af50e7a23eeb7b4963d7be2cb9e7beac64b1449c1e87ba SHA512 c3f20040d4dde1ae16f71a5c437a612915d09f0a0328bb184b068a38131c37c0c04bf42acbdc775f167da3cf10f49209a3226136629e001ea724518b70944c68
diff --git a/gui-apps/waypipe/waypipe-0.8.6.ebuild b/gui-apps/waypipe/waypipe-0.8.6.ebuild
new file mode 100644
index 000000000000..0d8968a8db52
--- /dev/null
+++ b/gui-apps/waypipe/waypipe-0.8.6.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit meson python-any-r1
+
+DESCRIPTION="Transparent network proxy for Wayland compositors"
+HOMEPAGE="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+else
+	SRC_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe/-/archive/v${PV}/${PN}-v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-v${PV}
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+WAYPIPE_FLAG_MAP_X86=( avx2:with_avx2 avx512f:with_avx512f sse3:with_sse3 )
+WAYPIPE_FLAG_MAP_ARM=( neon:with_neon_opts )
+WAYPIPE_FLAG_MAP=(
+	"${WAYPIPE_FLAG_MAP_X86[@]/#/cpu_flags_x86_}"
+	"${WAYPIPE_FLAG_MAP_ARM[@]/#/cpu_flags_arm_}"
+)
+
+IUSE="dmabuf ffmpeg lz4 man systemtap test vaapi zstd ${WAYPIPE_FLAG_MAP[@]%:*}"
+REQUIRED_USE="vaapi? ( ffmpeg )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dmabuf? (
+		media-libs/mesa[gbm(+),vaapi?,wayland]
+		x11-libs/libdrm
+	)
+	lz4? ( app-arch/lz4 )
+	systemtap? ( dev-util/systemtap )
+	vaapi? ( media-libs/libva[drm(+),wayland] )
+	ffmpeg? (
+		media-video/ffmpeg[x264,vaapi?]
+	)
+	zstd? ( app-arch/zstd )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+	test? ( dev-libs/weston[examples,headless,remoting,screen-sharing,wayland-compositor] )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use systemtap with_systemtap)
+		$(meson_feature dmabuf with_dmabuf)
+		$(meson_feature ffmpeg with_video)
+		$(meson_feature lz4 with_lz4)
+		$(meson_feature man man-pages)
+		$(meson_feature vaapi with_vaapi)
+		$(meson_feature zstd with_zstd)
+	)
+	local fl
+	for fl in "${WAYPIPE_FLAG_MAP[@]}"; do
+		emesonargs+=( $(meson_use "${fl%:*}" "${fl#*:}") )
+	done
+	meson_src_configure
+}
-- 
cgit v1.2.3-65-gdbad