From ca226b161a18e6bc3ad8af24d2ac2805e2f9aac5 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 10 Jul 2022 15:51:14 +0100
Subject: games-arcade/xbubble: EAPI 8

Signed-off-by: Sam James <sam@gentoo.org>
---
 games-arcade/xbubble/xbubble-0.5.8-r1.ebuild | 51 --------------------------
 games-arcade/xbubble/xbubble-0.5.8-r2.ebuild | 55 ++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+), 51 deletions(-)
 delete mode 100644 games-arcade/xbubble/xbubble-0.5.8-r1.ebuild
 create mode 100644 games-arcade/xbubble/xbubble-0.5.8-r2.ebuild

(limited to 'games-arcade')

diff --git a/games-arcade/xbubble/xbubble-0.5.8-r1.ebuild b/games-arcade/xbubble/xbubble-0.5.8-r1.ebuild
deleted file mode 100644
index 67c8f575299f..000000000000
--- a/games-arcade/xbubble/xbubble-0.5.8-r1.ebuild
+++ /dev/null
@@ -1,51 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit desktop
-
-DESCRIPTION="A Puzzle Bobble clone similar to Frozen-Bubble"
-HOMEPAGE="http://www.nongnu.org/xbubble/"
-SRC_URI="http://www.ibiblio.org/pub/mirrors/gnu/ftp/savannah/files/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~x86"
-IUSE="nls"
-
-RDEPEND="
-	x11-libs/libX11
-	x11-libs/libXt
-	media-libs/libpng:0=
-	nls? ( virtual/libintl )
-"
-DEPEND="${RDEPEND}
-	nls? ( sys-devel/gettext )
-"
-
-DOCS=( AUTHORS ChangeLog NEWS NetworkProtocol README TODO )
-
-src_prepare() {
-	default
-	eapply \
-		"${FILESDIR}"/${P}-xpaths.patch \
-		"${FILESDIR}"/${P}-locale.patch \
-		"${FILESDIR}"/${P}-libpng14.patch \
-		"${FILESDIR}"/${P}-png15.patch
-	sed -i \
-		-e '/^AM_CFLAGS/d' \
-		src/Makefile.in || die
-	sed -i \
-		-e '/^localedir/s:=.*:=/usr/share/locale:' \
-		configure po/Makefile.in.in || die
-}
-
-src_configure() {
-	econf $(use_enable nls)
-}
-
-src_install() {
-	default
-	newicon data/themes/fancy/Bubble_black_DEAD_01.png ${PN}.png
-	make_desktop_entry ${PN} XBubble
-}
diff --git a/games-arcade/xbubble/xbubble-0.5.8-r2.ebuild b/games-arcade/xbubble/xbubble-0.5.8-r2.ebuild
new file mode 100644
index 000000000000..812a69873e32
--- /dev/null
+++ b/games-arcade/xbubble/xbubble-0.5.8-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop
+
+DESCRIPTION="A Puzzle Bobble clone similar to Frozen-Bubble"
+HOMEPAGE="http://www.nongnu.org/xbubble/"
+SRC_URI="http://www.ibiblio.org/pub/mirrors/gnu/ftp/savannah/files/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXt
+	media-libs/libpng:=
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+DOCS=( AUTHORS ChangeLog NEWS NetworkProtocol README TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-xpaths.patch
+	"${FILESDIR}"/${P}-locale.patch
+	"${FILESDIR}"/${P}-libpng14.patch
+	"${FILESDIR}"/${P}-png15.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/^AM_CFLAGS/d' \
+		src/Makefile.in || die
+	sed -i \
+		-e '/^localedir/s:=.*:=/usr/share/locale:' \
+		configure po/Makefile.in.in || die
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+
+	default
+	newicon data/themes/fancy/Bubble_black_DEAD_01.png ${PN}.png
+	make_desktop_entry ${PN} XBubble
+}
-- 
cgit v1.2.3-65-gdbad