From 00117ca09fc8f3b3ee230e163c96b00eed3d5efd Mon Sep 17 00:00:00 2001
From: Gilles Dartiguelongue <eva@gentoo.org>
Date: Wed, 16 Aug 2017 12:17:13 +0200
Subject: dev-python/python-slip: version bump 0.6.1 → 0.6.5
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Fix homepage, bug #617614.

Package-Manager: Portage-2.3.7, Repoman-2.3.3
---
 dev-python/python-slip/python-slip-0.6.5.ebuild | 44 +++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-python/python-slip/python-slip-0.6.5.ebuild

(limited to 'dev-python/python-slip/python-slip-0.6.5.ebuild')

diff --git a/dev-python/python-slip/python-slip-0.6.5.ebuild b/dev-python/python-slip/python-slip-0.6.5.ebuild
new file mode 100644
index 000000000000..58abc1ead8da
--- /dev/null
+++ b/dev-python/python-slip/python-slip-0.6.5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_REQ_USE="xml"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Miscellaneous convenience, extension and workaround code for Python"
+HOMEPAGE="https://github.com/nphilipp/python-slip"
+SRC_URI="https://github.com/nphilipp/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dbus selinux"
+
+RDEPEND="
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		sys-auth/polkit )
+"
+DEPEND=""
+
+python_prepare_all() {
+	use selinux || epatch "${FILESDIR}"/${PN}-0.6.5-no-selinux.patch
+
+	# hard-disable slip.gtk since it did not get ported to gtk3+ and the only user
+	# of slip (firewalld) does not use it (upstream disables it for py3 already)
+	sed \
+		-e 's|sys.version_info.major == 2|False|' \
+		-e "s:@VERSION@:${PV}:" setup.py.in > setup.py || die "sed failed"
+
+	if ! use dbus; then
+		sed -e '/name="slip.dbus"/ s/\(.*\)/if 0:\n    \1/' \
+			-i setup.py || die "sed 2 failed"
+	fi
+
+	distutils-r1_python_prepare_all
+}
-- 
cgit v1.2.3-65-gdbad