From 005b9ea5c4cf7fa75dbb2a34e6b1f82c690f3d58 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Mon, 9 Jul 2018 08:20:14 +0200
Subject: dev-libs/libmirage: Bump to 3.2.0

---
 dev-libs/libmirage/Manifest               |  1 +
 dev-libs/libmirage/libmirage-3.2.0.ebuild | 52 +++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 dev-libs/libmirage/libmirage-3.2.0.ebuild

(limited to 'dev-libs/libmirage')

diff --git a/dev-libs/libmirage/Manifest b/dev-libs/libmirage/Manifest
index f25f291e9282..344af7497370 100644
--- a/dev-libs/libmirage/Manifest
+++ b/dev-libs/libmirage/Manifest
@@ -1 +1,2 @@
 DIST libmirage-3.1.0.tar.bz2 234649 BLAKE2B 1b0194fc6271454481ba752f2e7241d9aa69b8d1608dc059b17eb32ad78ee7721d0f85677511e97ccc6fd708690950d0ed6ab662cdff4ccd94804b1a5756542b SHA512 fcf49b171b6f84ad32cdeeb63def76e8bd5c5f33aadcc678e06d7388d0c351e8047beae6db9db7b69f704ab4db86aca4e8fb9817b2450c70b5f1d3d7a3760394
+DIST libmirage-3.2.0.tar.bz2 234214 BLAKE2B f2b8c42eed89efaeddb8051160c51814b4df45c1ca7cdb4cef683b86ea73dcd1446c6806588a9df0410da5b3971ce8945f2479022f21177237ee8b0d4b18d2d3 SHA512 15507154441b660f5a58e1101d4e6f9931a7640b90d3de5e387274c72be07f367b54a6be34dd31442bc504459414f611ffc39f86ff6a7381a820d059aef1d6d6
diff --git a/dev-libs/libmirage/libmirage-3.2.0.ebuild b/dev-libs/libmirage/libmirage-3.2.0.ebuild
new file mode 100644
index 000000000000..dde47a4856b6
--- /dev/null
+++ b/dev-libs/libmirage/libmirage-3.2.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="CD and DVD image access library"
+HOMEPAGE="http://cdemu.org"
+SRC_URI="mirror://sourceforge/cdemu/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0/11" # subslot = libmirage soname version
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="doc +introspection"
+
+RDEPEND=">=app-arch/bzip2-1:=
+	>=app-arch/xz-utils-5:=
+	>=dev-libs/glib-2.28:2
+	>=media-libs/libsamplerate-0.1:=
+	>=media-libs/libsndfile-1.0:=
+	sys-libs/zlib:=
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )"
+DEPEND="${RDEPEND}
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DGTKDOC_ENABLED="$(usex doc)"
+		-DINTROSPECTION_ENABLED="$(usex introspection)"
+		-DPOST_INSTALL_HOOKS=OFF # avoid sandbox violation, #487304
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	local DOCS=( AUTHORS README )
+	cmake-utils_src_install
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3-65-gdbad