From c4db39242214241b35d00927992aae7301cd9e45 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Sun, 12 Jun 2016 11:46:00 +0200
Subject: dev-libs/libintl: Bump to version 0.19.8.1

Removed old.

Package-Manager: portage-2.2.28
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-libs/libintl/Manifest                |  2 +-
 dev-libs/libintl/libintl-0.19.8.1.ebuild | 77 ++++++++++++++++++++++++++++++++
 dev-libs/libintl/libintl-0.19.8.ebuild   | 77 --------------------------------
 3 files changed, 78 insertions(+), 78 deletions(-)
 create mode 100644 dev-libs/libintl/libintl-0.19.8.1.ebuild
 delete mode 100644 dev-libs/libintl/libintl-0.19.8.ebuild

(limited to 'dev-libs/libintl')

diff --git a/dev-libs/libintl/Manifest b/dev-libs/libintl/Manifest
index 2736a31ee092..bad5989ce5dc 100644
--- a/dev-libs/libintl/Manifest
+++ b/dev-libs/libintl/Manifest
@@ -1,3 +1,3 @@
 DIST gettext-0.19.6.tar.gz 18619659 SHA256 ed4b4c19bd3a3034eb6769500a3592ff616759ef43cf30586dbb7a17c9dd695d SHA512 46adfd4a6d0038aba999658bebe51117e3ab3dc149a9054c1087d3e79ec7ba3371a7e78a8ca30a8872d162c2dc44aba6e67e4d64808c4f92e1e2bd674174f1db WHIRLPOOL 1988f9ddfd603734b4a632291925c8e5b31e7384eea1c6641d52aa58cb6b8f892e7664dd145a53435b7d2a4540ac65aeae1cb528a004c35832087c2820dafbcb
 DIST gettext-0.19.7.tar.gz 19235781 SHA256 5386d2a40500295783c6a52121adcf42a25519e2d23675950619c9e69558c23f SHA512 7ba89074d3eddd0b4a5e2980e1ec74b53c49b7a04a1fa91c70c4bc11ce9c30415e4df9d79698148eaaed325fb4feb25a340a2e8e01fbe86b1a66b1376a4c9e3d WHIRLPOOL eb51c4be7c0a92c5c33c16329003e21947e0b9d1583c4a785ae6836f81273ea7ec2823a0a28ae81c3b977f2148c0f3bd524949484383ff87510e1d2bc642a786
-DIST gettext-0.19.8.tar.gz 19977131 SHA256 3da4f6bd79685648ecf46dab51d66fcdddc156f41ed07e580a696a38ac61d48f SHA512 6d169ea1c0a2a39a7df6f65a372f1729a1fab94ab6b0cf04fd7fd7371eff1f409c433ea5ec3a8e39105d1eeea2ebbbbcd59433367ec2510ed4b59cecca4dd2e5 WHIRLPOOL ce4b1e8096d504d22c857d5eefb05b4c84a70918ff3710675550d997f80567713179a5013de16055ec5495db3f468c983e8b9ca6fcafce1efd41bfdb69de9267
+DIST gettext-0.19.8.1.tar.gz 19704011 SHA256 ff942af0e438ced4a8b0ea4b0b6e0d6d657157c5e2364de57baa279c1c125c43 SHA512 073042fa2dc48804c58e76f036130a669e19612c25427b0ab14d0b366b549a63751bf3af03bfd0745d7c4f72497a4b2aab26a3cc6de83189ce111679073878e1 WHIRLPOOL ef9aa9eef3067595dc725169075401dfad8ba15d6224d2b563e3421afa7c4dce9336a287147404273b772def811230b3758c005902ec90192e6ee4ac373d9a9a
diff --git a/dev-libs/libintl/libintl-0.19.8.1.ebuild b/dev-libs/libintl/libintl-0.19.8.1.ebuild
new file mode 100644
index 000000000000..a3cf14c1d3a3
--- /dev/null
+++ b/dev-libs/libintl/libintl-0.19.8.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+# Note: Keep version bumps in sync with sys-devel/gettext.
+
+EAPI="5"
+
+MY_P="gettext-${PV}"
+
+inherit multilib-minimal toolchain-funcs libtool
+
+DESCRIPTION="the GNU international library (split out of gettext)"
+HOMEPAGE="https://www.gnu.org/software/gettext/"
+SRC_URI="mirror://gnu/gettext/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="static-libs +threads"
+
+DEPEND=">=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]"
+# Block C libraries known to provide libintl.
+RDEPEND="${DEPEND}
+	!sys-libs/glibc
+	!sys-libs/musl
+	!<sys-devel/gettext-0.19.6-r1"
+
+S="${WORKDIR}/${MY_P}/gettext-runtime"
+
+src_prepare() {
+	# The libtool files are stored higher up, so make sure we run in the
+	# whole tree and not just the subdir we build.
+	elibtoolize "${WORKDIR}"
+}
+
+multilib_src_configure() {
+	local myconf=(
+		# Emacs support is now in a separate package.
+		--without-emacs
+		--without-lispdir
+		# Normally this controls nls behavior in general, but the libintl
+		# subdir is skipped unless this is explicitly set.  ugh.
+		--enable-nls
+		# This magic flag enables libintl.
+		--with-included-gettext
+		# The gettext package provides this library.
+		--disable-c++
+		--disable-libasprintf
+		# No java until someone cares.
+		--disable-java
+
+		$(use_enable static-libs static)
+		$(use_enable threads)
+	)
+	ECONF_SOURCE=${S} econf "${myconf[@]}"
+}
+
+multilib_src_compile() {
+	# We only need things in the intl/ subdir.
+	emake -C intl
+}
+
+multilib_src_install() {
+	# We only need things in the intl/ subdir.
+	emake DESTDIR="${D}" install -C intl
+
+	gen_usr_ldscript -a intl
+}
+
+multilib_src_install_all() {
+	use static-libs || prune_libtool_files --all
+
+	rm -f "${ED}"/usr/share/locale/locale.alias "${ED}"/usr/lib/charset.alias
+
+	dodoc AUTHORS ChangeLog NEWS README
+}
diff --git a/dev-libs/libintl/libintl-0.19.8.ebuild b/dev-libs/libintl/libintl-0.19.8.ebuild
deleted file mode 100644
index a3cf14c1d3a3..000000000000
--- a/dev-libs/libintl/libintl-0.19.8.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-# Note: Keep version bumps in sync with sys-devel/gettext.
-
-EAPI="5"
-
-MY_P="gettext-${PV}"
-
-inherit multilib-minimal toolchain-funcs libtool
-
-DESCRIPTION="the GNU international library (split out of gettext)"
-HOMEPAGE="https://www.gnu.org/software/gettext/"
-SRC_URI="mirror://gnu/gettext/${MY_P}.tar.gz"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
-IUSE="static-libs +threads"
-
-DEPEND=">=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]"
-# Block C libraries known to provide libintl.
-RDEPEND="${DEPEND}
-	!sys-libs/glibc
-	!sys-libs/musl
-	!<sys-devel/gettext-0.19.6-r1"
-
-S="${WORKDIR}/${MY_P}/gettext-runtime"
-
-src_prepare() {
-	# The libtool files are stored higher up, so make sure we run in the
-	# whole tree and not just the subdir we build.
-	elibtoolize "${WORKDIR}"
-}
-
-multilib_src_configure() {
-	local myconf=(
-		# Emacs support is now in a separate package.
-		--without-emacs
-		--without-lispdir
-		# Normally this controls nls behavior in general, but the libintl
-		# subdir is skipped unless this is explicitly set.  ugh.
-		--enable-nls
-		# This magic flag enables libintl.
-		--with-included-gettext
-		# The gettext package provides this library.
-		--disable-c++
-		--disable-libasprintf
-		# No java until someone cares.
-		--disable-java
-
-		$(use_enable static-libs static)
-		$(use_enable threads)
-	)
-	ECONF_SOURCE=${S} econf "${myconf[@]}"
-}
-
-multilib_src_compile() {
-	# We only need things in the intl/ subdir.
-	emake -C intl
-}
-
-multilib_src_install() {
-	# We only need things in the intl/ subdir.
-	emake DESTDIR="${D}" install -C intl
-
-	gen_usr_ldscript -a intl
-}
-
-multilib_src_install_all() {
-	use static-libs || prune_libtool_files --all
-
-	rm -f "${ED}"/usr/share/locale/locale.alias "${ED}"/usr/lib/charset.alias
-
-	dodoc AUTHORS ChangeLog NEWS README
-}
-- 
cgit v1.2.3-65-gdbad