1 files changed, 53 insertions, 0 deletions
diff --git a/dev-python/mako/mako-1.1.2.ebuild b/dev-python/mako/mako-1.1.2.ebuild
new file mode 100644
index 000000000000..c3b7f9e56394
--- /dev/null
+++ b/dev-python/mako/mako-1.1.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8}} )
+
+inherit distutils-r1 eutils
+
+MY_P=${P^}
+DESCRIPTION="A Python templating language"
+HOMEPAGE="https://www.makotemplates.org/ https://pypi.org/project/Mako/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${PN^}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc"
+
+RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/mako-1.1.1-pypy3-test.patch
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# seriously?
+	sed -i -e 's:from nose import:from unittest import:' \
+		test/__init__.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	rm -r doc/build || die
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Optional dependencies:"
+	optfeature "caching support" dev-python/beaker
+}