1 files changed, 48 insertions, 0 deletions
diff --git a/dev-libs/libyaml/libyaml-0.1.7.ebuild b/dev-libs/libyaml/libyaml-0.1.7.ebuild
new file mode 100644
index 000000000000..68185210b156
--- /dev/null
+++ b/dev-libs/libyaml/libyaml-0.1.7.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils libtool
+
+MY_P="${P/lib}"
+
+DESCRIPTION="YAML 1.1 parser and emitter written in C"
+HOMEPAGE="http://pyyaml.org/wiki/LibYAML"
+SRC_URI="http://pyyaml.org/download/${PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test static-libs"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	# conditionally remove tests
+	if ! use test; then
+		sed -i -e 's: tests::g' Makefile* || die
+	fi
+
+	elibtoolize  # for FreeMiNT
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	prune_libtool_files
+	use doc && dodoc -r doc/html
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		insinto /usr/share/doc/${PF}/examples
+		doins tests/example-*.c
+	fi
+}