x11-terms/st: Version 0.8.2

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/x11-terms/st/Manifest b/x11-terms/st/Manifest
index 909cf3330058..9d21a54ca606 100644
--- a/x11-terms/st/Manifest
+++ b/x11-terms/st/Manifest
@@ -1 +1,2 @@
 DIST st-0.8.1.tar.gz 45423 BLAKE2B e7f5d731ba86f37db4cda1f612a8f191f955d7ea8fd57c3fb142c695c41fda4d3b82a483bb3c1fff2d4ff66d9277ed22339c026bca4f4af740fc80cbbc7f3620 SHA512 787d35b0cc8b1435dad7809e9995bed3c7f781e012a4a43dd5ae3d670ebc0e4bc03a56ba3872ff8a3bdba316a41ba771c626adc8de0559296457a59170756c6b
+DIST st-0.8.2.tar.gz 44788 BLAKE2B cc7fc9040c6db1c903d0f7290e5cfd1c636b2d17b42645956583cc8fa883bc1f0631ffbd683e735a834ff96f90171d9d423801d84ce4c0686564498baa97bbc6 SHA512 eaaf5f2fe050ee768d16a9c8c295ba13315775b3a8a3201e020237a3dd217bfb811832d58477249000596289a6cb3287fbb39d6327fc90986af1c363e4b5bf8d
diff --git a/x11-terms/st/st-0.8.2.ebuild b/x11-terms/st/st-0.8.2.ebuild
new file mode 100644
index 000000000000..185bb03fd8f3
--- /dev/null
+++ b/x11-terms/st/st-0.8.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop multilib savedconfig toolchain-funcs
+
+DESCRIPTION="simple terminal implementation for X"
+HOMEPAGE="https://st.suckless.org/"
+SRC_URI="https://dl.suckless.org/st/${P}.tar.gz"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86"
+IUSE="savedconfig"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	dodoc TODO
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}