dev-util/diffoscope: add 216

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 110 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index e6e756271a93..18983e85ed89 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,2 +1,3 @@
 DIST diffoscope-207.tar.gz 2707223 BLAKE2B e20f21c9e0acc78cadfce082f874b3e3cbbbd26cfa5041012eb07a347f177724506d1263b6636c71c5304993e52b81e8ac1fa82ee7231d892346ede2d00de37f SHA512 ebbcf3e7e41f042626f2d175cea027392fc52f65dd11ded8e2a65ed3d58129fe4948e6129c2aec74d58d8f6b58855ada23be8231b426a9473b165eba0f182955
 DIST diffoscope-214.tar.gz 2710707 BLAKE2B 6acd7fa9c69ad831c6d362b805c2094b2f55d57fa87f69e9e153a99a71c90a67884796696df0d24d6b3c94c0b9a41736292d44208f4d8de4262eaa5f2eec6c90 SHA512 67a9b68ce5f7934747e30e41506d7e30f018673314b777ab86af89e3dd56212c442abe6e246741f7b842b5c58f14006442167cf9089823ba4ef1ba07e78eaaa7
+DIST diffoscope-216.tar.gz 2711117 BLAKE2B d4818fc89a511c2387c486a38df0b925a78b4676c0351c2cb3d81ee91856bb48a396e4f09d70d3ec7a67a302f11f94977f015fcf71d2865caea95f01aa80a23f SHA512 ba8ee78516770b623756dea8c48999cc1e4c731a0ac16a4ad38ed2d534ff867534bb31162c10664eda07ab22332e4dae5438a7d33de69c63c2cf25ba7c34a6be
diff --git a/dev-util/diffoscope/diffoscope-216.ebuild b/dev-util/diffoscope/diffoscope-216.ebuild
new file mode 100644
index 000000000000..d3cec4443ea4
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-216.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+)
+
+distutils_enable_tests pytest