dev-python/testtools: Version Bump

Package-Manager: portage-2.2.27
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/testtools/testtools-2.0.0.ebuild b/dev-python/testtools/testtools-2.0.0.ebuild
new file mode 100644
index 000000000000..367c8a723d05
--- /dev/null
+++ b/dev-python/testtools/testtools-2.0.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Extensions to the Python standard library unit testing framework"
+HOMEPAGE="https://github.com/testing-cabal/testtools"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+CDEPEND="
+	dev-python/extras[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-1.3.0[${PYTHON_USEDEP}]
+	dev-python/mimeparse[${PYTHON_USEDEP}]
+	>=dev-python/pbr-0.11[${PYTHON_USEDEP}]
+	dev-python/pyrsistent[${PYTHON_USEDEP}]
+	>=dev-python/unittest2-1.0.0[${PYTHON_USEDEP}]
+	dev-python/traceback2[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	"${PYTHON}" -m testtools.run testtools.tests.test_suite || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}