dev-python/pbr: Bump to 5.10.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-python/pbr/Manifest b/dev-python/pbr/Manifest
index 61894ff9cbb6..60888db34e69 100644
--- a/dev-python/pbr/Manifest
+++ b/dev-python/pbr/Manifest
@@ -1 +1,2 @@
+DIST pbr-5.10.0.tar.gz 127122 BLAKE2B 45a254629c2d1e73ce500edb5ba05f165dfaa9987bd62500490cdcceed11708878bc82441f218cf2f5a38b50301a2bcd0aabd0a5e5810346586d8d6463162ba9 SHA512 a5f4393407a17f4de5977483f3c7fa651780b9b9069a0a1898a5b511742262dfb06f891cfcb632c5b64ecfd041188095ceb880c6e71c99c81f0eace59e4e1976
 DIST pbr-5.9.0.tar.gz 126893 BLAKE2B 3f1d39c037afa7fe6d45b0b039968243e99717b347d1f1ada25023a64e7e683c0d83d2ce177e0f7c5f4cb65cd2a0eedd594b463d5d72bdc86560d811bd3f0cd3 SHA512 b36cc331664b91899a884bb1bc6980174ba2463db35c591d480d0b5a49dd37781132893e488c6a9238fbd2ec16589652d66b01a8c2701d02ff5c0b04e9c6121b
diff --git a/dev-python/pbr/pbr-5.10.0.ebuild b/dev-python/pbr/pbr-5.10.0.ebuild
new file mode 100644
index 000000000000..f1d5a256fa49
--- /dev/null
+++ b/dev-python/pbr/pbr-5.10.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{8..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="
+	https://opendev.org/openstack/pbr/
+	https://github.com/openstack/pbr/
+	https://pypi.org/project/pbr/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/setuptools-60.5.0[${PYTHON_USEDEP}]
+"
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and https://bugs.gentoo.org/show_bug.cgi?id=561038
+# docutils is needed for sphinx exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848
+# stestr is run as external tool
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# TODO: investigate
+	sed -e 's:test_console_script_develop:_&:' \
+		-e 's:test_console_script_install:_&:' \
+		-e 's:test_setup_py_keywords:_&:' \
+		-i pbr/tests/test_core.py || die
+	# network
+	rm pbr/tests/test_wsgi.py || die
+	# installs random packages via pip from the Internet
+	sed -e 's:test_requirement_parsing:_&:' \
+		-e 's:test_pep_517_support:_&:' \
+		-i pbr/tests/test_packaging.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Testing on ${EPYTHON} is not supported at the moment"
+		return
+	fi
+
+	eunittest -b
+}