From 865702a5b15f80d216c55ca784e3e0582b921a8c Mon Sep 17 00:00:00 2001
From: Takuya Wakazono <pastalian46@gmail.com>
Date: Tue, 20 Aug 2024 23:35:56 +0900
Subject: games-engines/nxengine-evo: fix deps

Closes: https://bugs.gentoo.org/921848
Closes: https://bugs.gentoo.org/932274
Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>
---
 .../nxengine-evo/nxengine-evo-2.6.5_p1-r1.ebuild   | 57 ++++++++++++++++++++++
 .../nxengine-evo/nxengine-evo-2.6.5_p1.ebuild      | 56 ---------------------
 2 files changed, 57 insertions(+), 56 deletions(-)
 create mode 100644 games-engines/nxengine-evo/nxengine-evo-2.6.5_p1-r1.ebuild
 delete mode 100644 games-engines/nxengine-evo/nxengine-evo-2.6.5_p1.ebuild

(limited to 'games-engines/nxengine-evo')

diff --git a/games-engines/nxengine-evo/nxengine-evo-2.6.5_p1-r1.ebuild b/games-engines/nxengine-evo/nxengine-evo-2.6.5_p1-r1.ebuild
new file mode 100644
index 000000000..0bfea748f
--- /dev/null
+++ b/games-engines/nxengine-evo/nxengine-evo-2.6.5_p1-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2018-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg cmake
+
+MY_PV="${PV/_p/-}"
+
+DESCRIPTION="rewrite of the jump-and-run platformer Doukutsu Monogatari(Cave Story)"
+HOMEPAGE="https://github.com/nxengine/nxengine-evo"
+SRC_URI="
+	https://github.com/nxengine/nxengine-evo/archive/v${MY_PV}.tar.gz -> ${PN}-${MY_PV}.tar.gz
+	https://www.cavestory.org/downloads/cavestoryen.zip
+"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-3 freedist"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	media-libs/libjpeg-turbo
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/sdl2-image[jpeg,png]
+	media-libs/sdl2-mixer
+"
+RDEPEND="${DEPEND}"
+BDEPEND="app-arch/unzip"
+
+PATCHES=(
+	"${FILESDIR}/nxengine-evo-2.6.5-1-gcc13.patch"
+)
+
+src_compile() {
+	cmake_src_compile
+
+	cp -r data "${WORKDIR}/CaveStory" || die
+	cd "${WORKDIR}/CaveStory" || die
+	"${BUILD_DIR}/nxextract" || die
+}
+
+src_install() {
+	cmake_src_install
+
+	cd "${WORKDIR}/CaveStory" || die
+
+	insinto /usr/share/nxengine
+	doins -r data
+
+	newdoc Readme.txt Doukutsu-Readme.txt
+	docinto html
+	newdoc Manual.html Doukutsu-Manual.html
+	dodoc -r Manual
+}
diff --git a/games-engines/nxengine-evo/nxengine-evo-2.6.5_p1.ebuild b/games-engines/nxengine-evo/nxengine-evo-2.6.5_p1.ebuild
deleted file mode 100644
index b92d95978..000000000
--- a/games-engines/nxengine-evo/nxengine-evo-2.6.5_p1.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 2018-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit xdg cmake
-
-MY_PV="${PV/_p/-}"
-
-DESCRIPTION="rewrite of the jump-and-run platformer Doukutsu Monogatari(Cave Story)"
-HOMEPAGE="https://github.com/nxengine/nxengine-evo http://nxengine.sourceforge.net/"
-SRC_URI="
-	https://github.com/nxengine/nxengine-evo/archive/v${MY_PV}.tar.gz -> ${PN}-${MY_PV}.tar.gz
-	https://www.cavestory.org/downloads/cavestoryen.zip
-"
-
-S="${WORKDIR}/${PN}-${MY_PV}"
-
-LICENSE="GPL-3 freedist"
-SLOT="0"
-KEYWORDS="~amd64"
-
-DEPEND="
-	media-libs/libpng:=
-	media-libs/libsdl2:=
-	media-libs/sdl2-mixer:=
-	media-libs/sdl2-ttf:=
-"
-RDEPEND="${DEPEND}"
-BDEPEND="app-arch/unzip"
-
-PATCHES=(
-	"${FILESDIR}/nxengine-evo-2.6.5-1-gcc13.patch"
-)
-
-src_compile() {
-	cmake_src_compile
-
-	cp -r data "${WORKDIR}/CaveStory" || die
-	cd "${WORKDIR}/CaveStory" || die
-	"${BUILD_DIR}/nxextract" || die
-}
-
-src_install() {
-	cmake_src_install
-
-	cd "${WORKDIR}/CaveStory" || die
-
-	insinto /usr/share/nxengine
-	doins -r data
-
-	newdoc Readme.txt Doukutsu-Readme.txt
-	docinto html
-	newdoc Manual.html Doukutsu-Manual.html
-	dodoc -r Manual
-}
-- 
cgit v1.2.3-65-gdbad