# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-0.7_alpha20060331-r1.ebuild,v 1.1 2006/04/03 23:10:56 genstef Exp $

inherit cvs nsplugins kde-functions

DESCRIPTION="Gnash is a GNU Flash movie player that supports many SWF v7 features"
HOMEPAGE="http://www.gnu.org/software/gnash"
SRC_URI=""
ECVS_SERVER="cvs.sv.gnu.org:/sources/${PN}"
ECVS_MODULE="${PN}"
ECVS_CO_OPTS="-D ${PV/0.7_alpha}"
ECVS_UP_OPTS="-dP ${ECVS_CO_OPTS}"
S=${WORKDIR}/${ECVS_MODULE}

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="dmalloc mp3 nsplugin nptl xml kde gtk"

DEPEND="sys-libs/zlib
	media-libs/jpeg
	media-libs/libpng
	|| (
		( x11-libs/libX11
		x11-libs/libXt
		x11-proto/xproto )
		virtual/x11
	)
	xml? ( dev-libs/libxml2 )
	dmalloc? ( dev-libs/dmalloc )
	mp3? ( media-libs/libmad )
	media-libs/libcaca
	media-libs/libogg
	media-libs/sdl-mixer
	sys-libs/gpm
	sys-libs/ncurses
	sys-libs/slang
	kde? ( kde-base/kdelibs )
	gtk? (
		dev-libs/glib
		dev-libs/atk
		x11-libs/pango
		x11-libs/cairo
		>x11-libs/gtk+-2
		x11-libs/gtkglext
	)
	virtual/opengl
	media-libs/libsdl"
RDEPEND="${DEPEND}"
set-kdedir

src_compile() {
	libtoolize --copy --force || die "libtoolize --copy --force failed"
	./autogen.sh || die "autogen.sh failed"
	econf \
		$(use_enable nptl pthreads) \
		$(use_enable dmalloc) \
		$(use_enable mp3) \
		$(use_enable xml) \
		$(use_enable kde klash) \
		$(use_enable gtk glext) \
		$(use_enable nsplugin plugin) \
		--with-plugindir=/opt/netscape/plugins \
		|| die "econf failed"
	# ugly workaround
	sed -i 's:exit $EXIT_FAILURE:#exit $EXIT_FAILURE:' libtool || die "failed"

	# the path is hardcoded
	sed -i s:/usr/local/bin/gnash:/usr/bin/gnash: plugin/plugin.cpp

	emake -j1 || die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die "make install failed"
	use nsplugin && inst_plugin /opt/netscape/plugins/libgnashplugin.so
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	ewarn "ALPHA"
	ewarn "gnash is still in heavy development"
	ewarn "please report gnash bugs upstream to the gnash devs"
}