blob: 5d33bc94d3d5b874851f13de1d257544194fdfcd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="Used to generate Makefile.in from Makefile.am"
HOMEPAGE="https://www.gnu.org/software/automake/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
# Use Gentoo versioning for slotting.
SLOT="${PV:0:3}"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86"
IUSE=""
RDEPEND="dev-lang/perl
>=sys-devel/automake-wrapper-10
>=sys-devel/autoconf-2.69:*
sys-devel/gnuconfig"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/automake-1.4-nls-nuisances.patch #121151
"${FILESDIR}"/${P}-target_hook.patch
"${FILESDIR}"/${P}-slot.patch
"${FILESDIR}"/${P}-test-fixes.patch #79505
"${FILESDIR}"/${PN}-1.10-ccnoco-ldflags.patch #203914
"${FILESDIR}"/${P}-CVE-2009-4029.patch #295357
"${FILESDIR}"/${PN}-1.5-perl-5.11.patch
)
src_prepare() {
default
export WANT_AUTOCONF=2.5
}
# slot the info pages. do this w/out munging the source so we don't have
# to depend on texinfo to regen things. #464146 (among others)
slot_info_pages() {
pushd "${ED}"/usr/share/info >/dev/null || die
rm -f dir || die
# Rewrite all the references to other pages.
# before: * aclocal-invocation: (automake)aclocal Invocation. Generating aclocal.m4.
# after: * aclocal-invocation v1.13: (automake-1.13)aclocal Invocation. Generating aclocal.m4.
local p pages=( *.info ) args=()
for p in "${pages[@]/%.info}" ; do
args+=(
-e "/START-INFO-DIR-ENTRY/,/END-INFO-DIR-ENTRY/s|: (${p})| v${SLOT}&|"
-e "s:(${p}):(${p}-${SLOT}):g"
)
done
sed -i "${args[@]}" * || die
# Rewrite all the file references, and rename them in the process.
local f d
for f in * ; do
d=${f/.info/-${SLOT}.info}
mv "${f}" "${d}" || die
sed -i -e "s:${f}:${d}:g" * || die
done
popd >/dev/null || die
}
src_install() {
default
slot_info_pages
local x
for x in aclocal automake ; do
mv "${ED}"/usr/bin/${x}{,-${SLOT}} || die
mv "${ED}"/usr/share/${x}{,-${SLOT}} || die
done
# remove all config.guess and config.sub files replacing them
# w/a symlink to a specific gnuconfig version
for x in guess sub ; do
dosym ../gnuconfig/config.${x} \
/usr/share/${PN}-${SLOT}/config.${x}
done
}
|
GitWeb