blob: a576ebf8f7589279bd546dc2f4a67ebf4d8defae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
data_ver=1.5
snd_trk_ver=1.0
snd_eff_ver=1.0
DESCRIPTION="Heroes Enjoy Riding Over Empty Slabs: similar to Tron and Nibbles"
HOMEPAGE="http://heroes.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
mirror://sourceforge/${PN}/${PN}-data-${data_ver}.tar.bz2
mirror://sourceforge/${PN}/${PN}-sound-tracks-${snd_trk_ver}.tar.bz2
mirror://sourceforge/${PN}/${PN}-sound-effects-${snd_eff_ver}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ggi nls sdl"
REQUIRED_USE="^^ ( ggi sdl )"
RESTRICT="test"
RDEPEND="
ggi? (
media-libs/libggi
media-libs/libgii
media-libs/libmikmod
)
nls? ( virtual/libintl )
sdl? (
media-libs/libsdl
media-libs/sdl-mixer
)"
DEPEND="${RDEPEND}"
BDEPEND="nls? ( sys-devel/gettext )"
PATCHES=(
"${FILESDIR}"/${P}-autotools.patch
"${FILESDIR}"/${P}-gcc4.patch
"${FILESDIR}"/${P}-cvs-segfault-fix.patch
"${FILESDIR}"/${P}-compilation.patch
"${FILESDIR}"/${P}-gcc10.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
local pkg
for pkg in ${A//.tar.bz2}; do
cd "${WORKDIR}"/${pkg} || die
econf \
--disable-heroes-debug \
--disable-optimizations \
$(use_with sdl) \
$(use_with sdl sdl-mixer) \
$(use_with ggi) \
$(use_with ggi mikmod) \
$(use_enable nls)
done
}
src_install() {
local pkg
for pkg in ${A//.tar.bz2} ; do
cd "${WORKDIR}"/${pkg} || die
emake DESTDIR="${D}" install
done
}
|
GitWeb
