dev-util/ragel/ragel-7.0.0.10-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools

DESCRIPTION="Compiles finite state machines from regular languages into executable code"
HOMEPAGE="https://www.colm.net/open-source/ragel/"
SRC_URI="https://www.colm.net/files/ragel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~x86 ~amd64-linux ~x86-linux"
IUSE="vim-syntax"

DEPEND="~dev-util/colm-0.13.0.5"
RDEPEND="${DEPEND}"
PATCHES=( "${FILESDIR}/${P}-use-pkginclude.patch" )

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	econf --disable-static
}

src_test() {
	cd "${S}"/test || die
	./runtests.in || die
}

src_install() {
	if use vim-syntax; then
		insinto /usr/share/vim/vimfiles/syntax
		doins ragel.vim
	fi
	default
	find "${D}" -name '*.la' -delete || die
}