From a8bb9598578229d466cd6e82a1d9f3aeafe7d488 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 27 Jun 2017 19:20:42 +0200
Subject: net-libs/libktorrent: Block dev-libs/botan[gmp] for runtime crashes
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

See also: https://github.com/randombit/botan/issues/1090
Thanks-to: Andrius Štikonas <andrius@stikonas.eu>

Package-Manager: Portage-2.3.6, Repoman-2.3.1
---
 net-libs/libktorrent/libktorrent-2.0.1-r1.ebuild | 72 ++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 net-libs/libktorrent/libktorrent-2.0.1-r1.ebuild

(limited to 'net-libs/libktorrent')

diff --git a/net-libs/libktorrent/libktorrent-2.0.1-r1.ebuild b/net-libs/libktorrent/libktorrent-2.0.1-r1.ebuild
new file mode 100644
index 000000000000..139323c86d1c
--- /dev/null
+++ b/net-libs/libktorrent/libktorrent-2.0.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} != 9999* ]]; then
+	inherit versionator
+	# upstream likes to skip that _ in beta releases
+	MY_PV="${PV/_/}"
+	KTORRENT_VERSION=$(($(get_major_version)+3)).$(get_version_component_range 2 ${MY_PV})
+	MY_P="${PN}-${MY_PV}"
+
+	SRC_URI="mirror://kde/stable/ktorrent/${KTORRENT_VERSION}/${MY_P}.tar.xz"
+	S="${WORKDIR}"/"${MY_P}"
+
+	KEYWORDS="amd64 ~arm x86"
+fi
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="BitTorrent library based on KDE Frameworks"
+HOMEPAGE="https://www.kde.org/applications/internet/ktorrent/"
+
+LICENSE="GPL-2+"
+IUSE=""
+
+COMMON_DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep solid)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	app-crypt/qca:2[qt5]
+	>=dev-libs/gmp-6.0.0a:0=
+	dev-libs/libgcrypt:0=
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	sys-devel/gettext
+"
+RDEPEND="${COMMON_DEPEND}
+	!net-libs/libktorrent:4
+	!dev-libs/botan[gmp(-)]
+"
+
+src_prepare() {
+	kde5_src_prepare
+
+	# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
+	sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
+		CMakeLists.txt || die
+	sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
+		LibKTorrentConfig.cmake.in || die
+
+	# do not build non-installed example binary
+	sed -i -e "/add_subdirectory(examples)/d" CMakeLists.txt || die
+
+	if ! use test ; then
+		sed -i -e "/add_subdirectory(testlib)/d" CMakeLists.txt || die
+		sed -i -e "/add_subdirectory(tests)/d" \
+			src/{datachecker,dht,diskio,download,magnet,mse,net,peer,util,utp,torrent}/CMakeLists.txt \
+			|| die "Failed to remove tests"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad